DifferentiationInterface.jl/DifferentiationInterface/ext/DifferentiationInterfaceTrackerExt/DifferentiationInterfaceTrackerExt.jl at 4a1bb404799d5544b9684e0b1c6bbae355ca97fe · JuliaDiff/DifferentiationInterface.jl · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
module DifferentiationInterfaceTrackerExt

using ADTypes: AutoTracker
import DifferentiationInterface as DI
using Tracker: Tracker, back, data, forward, gradient, jacobian, param, withgradient

DI.check_available(::AutoTracker) = true
DI.inplace_support(::AutoTracker) = DI.InPlaceNotSupported()

## Pullback

struct TrackerPullbackPrepSamePoint{SIG, Y, PB} <: DI.PullbackPrep{SIG}
    _sig::Val{SIG}
    y::Y
    pb::PB
end

function DI.prepare_pullback_nokwarg(
        strict::Val,
        f,
        backend::AutoTracker,
        x,
        ty::NTuple,
        contexts::Vararg{DI.GeneralizedConstant, C}
    ) where {C}
    _sig = DI.signature(f, backend, x, ty, contexts...; strict)
    return DI.NoPullbackPrep(_sig)
end

function DI.prepare_pullback_same_point(
        f,
        prep::DI.NoPullbackPrep,
        backend::AutoTracker,
        x,
        ty::NTuple,
        contexts::Vararg{DI.GeneralizedConstant, C},
    ) where {C}
    DI.check_prep(f, prep, backend, x, ty, contexts...)
    _sig = DI.signature(f, backend, x, ty, contexts...; strict = DI.is_strict(prep))
    y, pb = forward(f, x, map(DI.unwrap, contexts)...)
    return TrackerPullbackPrepSamePoint(_sig, y, pb)
end

function DI.value_and_pullback(
        f,
        prep::DI.NoPullbackPrep,
        backend::AutoTracker,
        x,
        ty::NTuple,
        contexts::Vararg{DI.GeneralizedConstant, C},
    ) where {C}
    DI.check_prep(f, prep, backend, x, ty, contexts...)
    y, pb = forward(f, x, map(DI.unwrap, contexts)...)
    tx = map(ty) do dy
        data(first(pb(dy)))
    end
    return y, tx
end

function DI.value_and_pullback(
        f,
        prep::TrackerPullbackPrepSamePoint,
        backend::AutoTracker,
        x,
        ty::NTuple,
        contexts::Vararg{DI.GeneralizedConstant, C},
    ) where {C}
    DI.check_prep(f, prep, backend, x, ty, contexts...)
    (; y, pb) = prep
    tx = map(ty) do dy
        data(first(pb(dy)))
    end
    return copy(y), tx
end

function DI.pullback(
        f,
        prep::TrackerPullbackPrepSamePoint,
        backend::AutoTracker,
        x,
        ty::NTuple,
        contexts::Vararg{DI.GeneralizedConstant, C},
    ) where {C}
    DI.check_prep(f, prep, backend, x, ty, contexts...)
    (; pb) = prep
    tx = map(ty) do dy
        data(first(pb(dy)))
    end
    return tx
end

## Gradient

function DI.prepare_gradient_nokwarg(
        strict::Val, f, backend::AutoTracker, x, contexts::Vararg{DI.GeneralizedConstant, C}
    ) where {C}
    _sig = DI.signature(f, backend, x, contexts...; strict)
    return DI.NoGradientPrep(_sig)
end

function DI.value_and_gradient(
        f,
        prep::DI.NoGradientPrep,
        backend::AutoTracker,
        x,
        contexts::Vararg{DI.GeneralizedConstant, C},
    ) where {C}
    DI.check_prep(f, prep, backend, x, contexts...)
    (; val, grad) = withgradient(f, x, map(DI.unwrap, contexts)...)
    return val, data(first(grad))
end

function DI.gradient(
        f,
        prep::DI.NoGradientPrep,
        backend::AutoTracker,
        x,
        contexts::Vararg{DI.GeneralizedConstant, C},
    ) where {C}
    DI.check_prep(f, prep, backend, x, contexts...)
    (; grad) = withgradient(f, x, map(DI.unwrap, contexts)...)
    return data(first(grad))
end

function DI.value_and_gradient!(
        f,
        grad,
        prep::DI.NoGradientPrep,
        backend::AutoTracker,
        x,
        contexts::Vararg{DI.GeneralizedConstant, C},
    ) where {C}
    DI.check_prep(f, prep, backend, x, contexts...)
    y, new_grad = DI.value_and_gradient(f, prep, backend, x, contexts...)
    return y, copy!(grad, new_grad)
end

function DI.gradient!(
        f,
        grad,
        prep::DI.NoGradientPrep,
        backend::AutoTracker,
        x,
        contexts::Vararg{DI.GeneralizedConstant, C},
    ) where {C}
    DI.check_prep(f, prep, backend, x, contexts...)
    return copy!(grad, DI.gradient(f, prep, backend, x, contexts...))
end

end