Initial commit

Author: kamil cybulski

.github/workflows/test.yml

@@ -0,0 +1,28 @@
+name: Test
+
+on:
+  push:
+    branches: [ main ]
+  pull_request:
+    branches: [ main ]
+
+jobs:
+
+  test:
+    runs-on: ubuntu-latest
+    steps:
+    - uses: actions/checkout@v2
+
+    - name: Set up Go
+      uses: actions/setup-go@v2
+      with:
+        go-version: 1.18
+
+    - name: Run tests
+      working-directory: ./test
+      run: go test -v
+      env:
+        UPCLOUD_USERNAME: ${{ secrets.UPCLOUD_USERNAME }}
+        UPCLOUD_PASSWORD: ${{ secrets.UPCLOUD_PASSWORD }}
+        CLOUDFLARE_API_TOKEN: ${{ secrets.CLOUDFLARE_API_TOKEN }}
+        TF_VAR_cloudflare_zone_id: ${{ secrets. CLOUDFLARE_ZONE_ID }}

.gitignore

@@ -0,0 +1,4 @@
+.terraform/
+.terraform.lock.hcl
+terraform.tfstate
+terraform.tfstate.backup

LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2022 UpCloud Ltd
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

README.md

@@ -0,0 +1,17 @@
+# UpCloud Basic Loadbalancer
+
+Terraform module which creates a basic load balancer setup with with automatic SSL certificate.
+
+## Usage
+```hcl
+module "load_balancer" {
+  source = "UpCloudLtd/basic-loadbalancer/upcloud"
+
+  name                = "my_loadbalancer"
+  zone                = "pl-waw1"
+  network             = upcloud_network.my_network.id
+  backend_servers     = ["10.0.1.3", "10.0.1.4", "10.0.1.5"]
+  backend_server_port = 3000
+  domains             = ["my.domain.net"]
+}
+```

examples/basic/README.md

@@ -0,0 +1,5 @@
+# Basic example
+
+A simple example with 3 servers and a load balancer that distributes the traffic between them. The example assumes that each of the servers has some application listening on port 3000.
+
+Once you deploy it, go to your domain settings and add a CNAME record that points to the `lb_url` output variable. After the change gets propagated, all the traffic to your domain (`my.domain.com` in this example) will be distributed among the 3 servers.

examples/basic/main.tf

@@ -0,0 +1,58 @@
+terraform {
+  required_providers {
+    upcloud = {
+      source  = "UpCloudLtd/upcloud"
+      version = "~> 2.4"
+    }
+  }
+}
+
+provider "upcloud" {}
+
+resource "upcloud_network" "network" {
+  name = "my_network"
+  zone = "pl-waw1"
+
+  ip_network {
+    family  = "IPv4"
+    address = "10.0.1.0/24"
+    dhcp    = true
+  }
+}
+
+resource "upcloud_server" "webservers" {
+  count    = 3
+  hostname = "webserver${count.index}"
+  title    = "webserver_${count.index}"
+  zone     = "pl-waw1"
+  plan     = "1xCPU-2GB"
+
+  template {
+    storage = "Ubuntu Server 20.04 LTS (Focal Fossa)"
+    size    = 25
+  }
+
+  network_interface {
+    type = "utility"
+  }
+
+  network_interface {
+    type    = "private"
+    network = upcloud_network.network.id
+  }
+}
+
+module "load_balancer" {
+  source = "UpCloudLtd/basic-loadbalancer/upcloud"
+
+  name                = "my_loadbalancer"
+  zone                = "pl-waw1"
+  network             = upcloud_network.network.id
+  backend_servers     = [for v in upcloud_server.webservers : v.network_interface.1.ip_address]
+  backend_server_port = 3000
+  domains             = ["my.domain.net"]
+}
+
+output "lb_url" {
+  value = module.load_balancer.dns_name
+}

examples/with-additional-rules/README.md

@@ -0,0 +1,3 @@
+# Basic example with additional rules
+
+This example shows how to attach additional frontend rules to load balancer. The module has a `frontend_id` output variable, which allows you to easily add rules to it.

examples/with-additional-rules/main.tf

@@ -0,0 +1,31 @@
+# Rest of the configuration omitted for brevity
+
+module "load_balancer" {
+  source = "UpCloudLtd/basic-loadbalancer/upcloud"
+
+  name            = "my_loadbalancer"
+  zone            = "pl-waw1"
+  network         = upcloud_network.my_network.id
+  backend_servers = ["10.0.1.3", "10.0.1.4", "10.0.1.5"]
+  domains         = ["my.domain.net"]
+}
+
+resource "upcloud_loadbalancer_frontend_rule" "some_rule" {
+  frontend = module.load_balancer.frontend_id
+  name     = "some_rule"
+  priority = 10
+
+  matchers {
+    url_param {
+      method = "exact"
+      name   = "secret"
+      value  = "1"
+    }
+  }
+
+  actions {
+    http_redirect {
+      location = "/super-secret-place"
+    }
+  }
+}

main.tf

@@ -0,0 +1,52 @@
+terraform {
+  required_providers {
+    upcloud = {
+      source  = "UpCloudLtd/upcloud"
+      version = "~> 2.4"
+    }
+  }
+}
+
+resource "upcloud_loadbalancer" "main" {
+  configured_status = "started"
+  name              = var.name
+  plan              = var.plan
+  zone              = var.zone
+  network           = var.network
+}
+
+resource "upcloud_loadbalancer_backend" "main" {
+  loadbalancer = upcloud_loadbalancer.main.id
+  name         = "main"
+}
+
+resource "upcloud_loadbalancer_static_backend_member" "main" {
+  count        = length(var.backend_servers)
+  backend      = upcloud_loadbalancer_backend.main.id
+  name         = "member_${count.index}"
+  ip           = var.backend_servers[count.index]
+  port         = var.backend_server_port
+  max_sessions = var.max_server_sessions
+  enabled      = true
+  weight       = 100
+}
+
+resource "upcloud_loadbalancer_frontend" "main" {
+  loadbalancer         = upcloud_loadbalancer.main.id
+  name                 = "main"
+  mode                 = "http"
+  port                 = var.frontend_port
+  default_backend_name = upcloud_loadbalancer_backend.main.name
+}
+
+resource "upcloud_loadbalancer_dynamic_certificate_bundle" "main" {
+  name      = "main"
+  hostnames = var.domains
+  key_type  = "rsa"
+}
+
+resource "upcloud_loadbalancer_frontend_tls_config" "main" {
+  frontend           = upcloud_loadbalancer_frontend.main.id
+  name               = "main"
+  certificate_bundle = upcloud_loadbalancer_dynamic_certificate_bundle.main.id
+}

outputs.tf

@@ -0,0 +1,23 @@
+output "id" {
+  value = upcloud_loadbalancer.main.id
+}
+
+output "dns_name" {
+  value = upcloud_loadbalancer.main.dns_name
+}
+
+output "backend_name" {
+  value = upcloud_loadbalancer_backend.main.name
+}
+
+output "backend_id" {
+  value = upcloud_loadbalancer_backend.main.id
+}
+
+output "frontend_name" {
+  value = upcloud_loadbalancer_frontend.main.name
+}
+
+output "frontend_id" {
+  value = upcloud_loadbalancer_frontend.main.id
+}