rustix: add Meson build to CI to guard Android use cases

Rustix has gone back-and-forth on it's policy on Android.
Android platform developers don't want a dependency on
linux-raw-sys.  This is documented here:

  #1095
  #1478
  rust-vsock/vsock-rs#60

Android app developers seem to want to use linux-raw-sys though:

#1528

The Android platform developers don't REALLY care about
the cargo build though.

CI/CD testing on the particular build options Android likes
is useful.

This MR adds another non-cargo build system (Meson) to the
CI/CD, that mirrors the options Android likes.

Meson is renowned for being a easy-to-maintain build system and
arguably the favorite among Linux-distro maintainers.

Right now, meson currently does not use Cargo.toml as a source
of truth for dependency, since a dependency's build.rs file can
basically do anything, and there's no way for an external build
system to determine a build.rs file is doing [1].  As such,
the standard way to include dependencies is are meson subprojects,
for each dependency.  There are various proposals to improve the
situation [2], but those would require a bleeding edge meson
not in CI/CD bots yet.

That said, there's an easy way to test from the root of the
directory:
   sudo apt install meson ninja-build
   meson setup rustix-build
   ninja -C rustix-build

Meson closely mirrors what Android does.  By adding it here, we
ensure the continue use of Rustix in core Android platform code.

[1] mesonbuild/meson#2173
[2] mesonbuild/meson#15223

Author: gurchetansingh

.github/workflows/main.yml

@@ -887,3 +887,75 @@ jobs:
         cargo test --verbose --features=all-apis --release --workspace -- --nocapture
       env:
         RUST_BACKTRACE: full
+
+  meson-musl:
+    name: Meson Musl
+    runs-on: ubuntu-latest
+    steps:
+    - uses: actions/checkout@v4
+      with:
+        submodules: true
+    - uses: ./.github/actions/install-rust
+      with:
+        toolchain: stable
+    - name: Install target
+      run: rustup target add x86_64-unknown-linux-musl
+    - name: Install Meson and Ninja
+      run: sudo apt-get update && sudo apt-get install -y meson ninja-build musl-tools
+    - name: Create cross file
+      run: |
+        cat <<EOF > cross_file_musl_ci.txt
+        [binaries]
+        c = 'gcc'
+        rust = ['rustc', '--target', 'x86_64-unknown-linux-musl']
+
+        [host_machine]
+        system = 'linux'
+        cpu_family = 'x86_64'
+        cpu = 'x86_64'
+        endian = 'little'
+        EOF
+    - name: Meson setup
+      run: meson setup build-musl --cross-file cross_file_musl_ci.txt
+    - name: Meson compile
+      run: meson compile -C build-musl
+
+  meson-android:
+    name: Meson Android
+    runs-on: ubuntu-latest
+    steps:
+    - uses: actions/checkout@v4
+      with:
+        submodules: true
+    - uses: ./.github/actions/install-rust
+      with:
+        toolchain: stable
+    - name: Install target
+      run: rustup target add x86_64-linux-android
+    - name: Install Meson and Ninja
+      run: sudo apt-get update && sudo apt-get install -y meson ninja-build
+    - name: Setup NDK
+      uses: nttld/setup-ndk@v1
+      id: setup-ndk
+      with:
+        ndk-version: r27b
+    - name: Create cross file
+      run: |
+        cat <<EOF > cross_file_android_ci.txt
+        [binaries]
+        c = '${{ steps.setup-ndk.outputs.ndk-path }}/toolchains/llvm/prebuilt/linux-x86_64/bin/x86_64-linux-android30-clang'
+        cpp = '${{ steps.setup-ndk.outputs.ndk-path }}/toolchains/llvm/prebuilt/linux-x86_64/bin/x86_64-linux-android30-clang++'
+        ar = '${{ steps.setup-ndk.outputs.ndk-path }}/toolchains/llvm/prebuilt/linux-x86_64/bin/llvm-ar'
+        strip = '${{ steps.setup-ndk.outputs.ndk-path }}/toolchains/llvm/prebuilt/linux-x86_64/bin/llvm-strip'
+        rust = ['rustc', '--target', 'x86_64-linux-android']
+
+        [host_machine]
+        system = 'android'
+        cpu_family = 'x86_64'
+        cpu = 'x86_64'
+        endian = 'little'
+        EOF
+    - name: Meson setup
+      run: meson setup build-android --cross-file cross_file_android_ci.txt
+    - name: Meson compile
+      run: meson compile -C build-android

meson.build

@@ -0,0 +1,46 @@
+# Copyright © 2026 Google
+# SPDX-License-Identifier: MIT
+
+project(
+  'rustix',
+  'rust',
+  version : '1.1.4',
+  license : 'Apache-2.0 WITH LLVM-exception OR Apache-2.0 OR MIT',
+)
+
+dep_errno = dependency('errno-0.3-rs', fallback: ['errno-0.3-rs', 'dep_errno'])
+dep_libc = dependency('libc-0.2-rs', fallback: ['libc-0.2-rs', 'dep_libc'])
+dep_bitflags = dependency('bitflags-2-rs', fallback: ['bitflags-2-rs', 'dep_bitflags'])
+
+rustix_args = [
+  '--cfg', 'libc',
+  '--cfg', 'feature="use-libc"',
+]
+
+os_deps = []
+if host_machine.system() == 'linux' or host_machine.system() == 'android'
+  rustix_args += [
+  '--cfg', 'linux_like',
+  '--cfg', 'linux_kernel',
+  '--cfg', 'feature="std"',
+  '--cfg', 'feature="alloc"',
+  '--cfg', 'feature="event"',
+  '--cfg', 'feature="fs"',
+  '--cfg', 'feature="mm"',
+  '--cfg', 'feature="net"',
+  '--cfg', 'feature="param"',
+  '--cfg', 'feature="pipe"',
+  '--cfg', 'feature="thread"',
+]
+elif host_machine.system() == 'windows'
+  os_deps += [dependency('windows-sys-0.6-rs', fallback: ['windows-sys-0.6-rs', 'dep_windows_sys'])]
+endif
+
+lib = static_library(
+  'rustix',
+  'src/lib.rs',
+  override_options : ['rust_std=2021', 'build.rust_std=2021'],
+  dependencies : [dep_errno, dep_libc, dep_bitflags] + os_deps,
+  rust_abi : 'rust',
+  rust_args: rustix_args,
+)

subprojects/bitflags-2-rs.wrap

@@ -0,0 +1,6 @@
+[wrap-file]
+directory = bitflags-2.9.1
+source_url = https://crates.io/api/v1/crates/bitflags/2.9.1/download
+source_filename = bitflags-2.9.1.tar.gz
+source_hash = 1b8e56985ec62d17e9c1001dc89c88ecd7dc08e47eba5ec7c29c7b5eeecde967
+patch_directory = bitflags-2-rs

subprojects/errno-0.3-rs.wrap

@@ -0,0 +1,6 @@
+[wrap-file]
+directory = errno-0.3.12
+source_url = https://crates.io/api/v1/crates/errno/0.3.12/download
+source_filename = errno-0.3.12.tar.gz
+source_hash = cea14ef9355e3beab063703aa9dab15afd25f0667c341310c1e5274bb1d0da18
+patch_directory = errno-0.3-rs

subprojects/libc-0.2-rs.wrap

@@ -0,0 +1,6 @@
+[wrap-file]
+directory = libc-0.2.177
+source_url = https://crates.io/api/v1/crates/libc/0.2.177/download
+source_filename = libc-0.2.177.tar.gz
+source_hash = 2874a2af47a2325c2001a6e6fad9b16a53b802102b528163885171cf92b15976
+patch_directory = libc-0.2-rs

subprojects/packagefiles/bitflags-2-rs/meson.build

@@ -0,0 +1,21 @@
+# Copyright © 2026 Google
+# SPDX-License-Identifier: MIT
+
+project(
+  'bitflags',
+  'rust',
+  version : '2.9.1',
+  license : 'MIT OR Apache-2.0',
+  meson_version : '>= 1.3.0',
+)
+
+lib = static_library(
+  'bitflags',
+  'src/lib.rs',
+  override_options : ['rust_std=2021', 'build.rust_std=2021', 'warning_level=0'],
+  rust_abi : 'rust',
+)
+
+dep_bitflags = declare_dependency(
+  link_with : [lib]
+)

subprojects/packagefiles/errno-0.3-rs/meson.build

@@ -0,0 +1,28 @@
+# Copyright © 2026 Google
+# SPDX-License-Identifier: MIT
+
+project(
+  'errno',
+  'rust',
+  version : '0.3.12',
+  license : 'MIT OR Apache-2.0',
+  meson_version : '>= 1.3.0',
+)
+
+os_deps = []
+libc = subproject('libc-0.2-rs').get_variable('lib')
+if host_machine.system() == 'windows'
+  os_deps += subproject('windows-sys-0.6-rs').get_variable('lib')
+endif
+
+lib = static_library(
+  'libc_errno',
+  'src/lib.rs',
+  override_options : ['rust_std=2018', 'build.rust_std=2018', 'warning_level=0'],
+  link_with: [libc] + os_deps,
+  rust_abi : 'rust',
+)
+
+dep_errno = declare_dependency(
+  link_with : [lib]
+)

subprojects/packagefiles/libc-0.2-rs/meson.build

@@ -0,0 +1,42 @@
+# Copyright © 2026 Google
+# SPDX-License-Identifier: MIT
+
+project(
+  'libc',
+  'rust',
+  version : '0.2.177',
+  license : 'MIT OR Apache-2.0',
+  meson_version : '>= 1.3.0',
+)
+
+libc_args = [
+  '--cfg', 'feature="default"',
+  '--cfg', 'feature="extra_traits"',
+  '--cfg', 'feature="std"',
+  '--cfg', 'freebsd11',
+  '--cfg', 'libc_align',
+  '--cfg', 'libc_cfg_target_vendor',
+  '--cfg', 'libc_const_extern_fn',
+  '--cfg', 'libc_const_size_of',
+  '--cfg', 'libc_core_cvoid',
+  '--cfg', 'libc_int128',
+  '--cfg', 'libc_long_array',
+  '--cfg', 'libc_non_exhaustive',
+  '--cfg', 'libc_packedN',
+  '--cfg', 'libc_priv_mod_use',
+  '--cfg', 'libc_ptr_addr_of',
+  '--cfg', 'libc_underscore_const_names',
+  '--cfg', 'libc_union',
+]
+
+lib = static_library(
+  'libc',
+  'src/lib.rs',
+  rust_abi : 'rust',
+  override_options : ['rust_std=2021', 'build.rust_std=2021', 'warning_level=0'],
+  rust_args: libc_args,
+)
+
+dep_libc = declare_dependency(
+  link_with : [lib]
+)