Remove dependency on pest and pest-ast.

This commit removes the dependency on `pest` and `pest-ast`.

A custom lexer is now implemented using `logos`; this allows for easy parsing
of doc comments at any point in the token stream.

The blackbox of `pest-ast` has been removed in favor of implementing a `Parse`
and `Peek` trait on the AST types. AST types no longer have to mirror the pest
grammar, so they have been simplified.

Top-level resource declarations have been removed from the grammar as they must
appear inside of interface and world declarations.

`bail!` has been removed in parsing and resolution in favor of custom
`thiserror`-derived error types.

Error reporting has been improved with more colors and removing redundant
information.

No new tests were added; parsing test baselines have substantial changes as a
result of the AST simplification.

Resolution failure test baselines have changed as a result of the error
formatting changes, but the error messages themselves should remain the same.

Author: peterhuene

Cargo.lock

@@ -40,17 +40,16 @@ wasmparser = "0.115.0"
 wit-component = "0.16.0"
 anyhow = "1.0.75"
 clap = { version = "4.4.6", features = ["derive"] }
-pest = "2.7.4"
-pest_derive = "2.7.4"
-from-pest = "0.3.2"
-pest-ast = "0.3.4"
 semver = "1.0.20"
 pretty_env_logger = "0.5.0"
 log = "0.4.20"
 tokio = { version = "1.33.0", default-features = false, features = ["macros", "rt-multi-thread"] }
-owo-colors = "3.5.0"
+owo-colors = { version = "3.5.0", features = ["supports-colors"] }
 indexmap = { version = "2.0.2", features = ["serde"] }
 id-arena = "2.2.1"
 serde = { version = "1.0.189", features = ["derive"] }
 serde_json = "1.0.107"
 wat = "1.0.77"
+logos = "0.13.0"
+thiserror = "1.0.50"
+smallvec = "1.11.1"

Cargo.toml

@@ -1 +1,117 @@
-# wac
+# WAC grammar
+
+The current WAC grammar:
+
+```ebnf
+document  ::= statement*
+statement ::= import-statement 
+            | type-statement
+            | let-statement
+            | export-statement
+
+import-statement ::= 'import' id ('with' string)? ':' import-type ';'
+import-type      ::= package-path | func-type | inline-interface | id
+package-path     ::= package-name ('/' id)+ ('@' package-version)?
+package-name     ::= id (':' id)+
+package-version  ::= <SEMVER>
+
+type-statement      ::= interface-decl | world-decl | type-decl
+interface-decl      ::= 'interface' id '{' interface-item* '}'
+interface-item      ::= use-type | item-type-decl | interface-export
+use-type            ::= 'use' use-path '.' '{' use-items '}' ';'
+use-path            ::= package-path | id
+use-items           ::= use-item (',' use-item)* ','?
+use-item            ::= id ('as' id)? 
+interface-export    ::= id ':' func-type-ref ';'
+world-decl          ::= 'world' id '{' world-item* '}'
+world-item          ::= use-type
+                      | item-type-decl
+                      | world-import
+                      | world-export
+                      | world-include
+world-import        ::= 'import' world-item-path ';'
+world-export        ::= 'export' world-item-path ';'
+world-item-path     ::= named-world-item | package-path | id
+named-world-item    ::= id ':' extern-type
+extern-type         ::= func-type | inline-interface | id
+inline-interface    ::= 'interface' '{' interface-item* '}'
+world-include       ::= 'include' world-ref ('with' '{' world-include-items '}')? ';'
+world-include-items ::= world-include-item (',' world-include-item)* ','?
+world-include-item  ::= id 'as' id
+world-ref           ::= package-path | id
+type-decl           ::= variant-decl | record-decl | flags-decl | enum-decl | type-alias
+item-type-decl      ::= resource-decl | type-decl
+resource-decl       ::= 'resource' id '{' resource-item* '}'
+resource-item       ::= constructor | method
+constructor         ::= 'constructor' param-list
+method              ::= id ':' 'static'? func-type-ref
+variant-decl        ::= 'variant' id '{' variant-cases '}'
+variant-cases       ::= variant-case (',' variant-case)* ','?
+variant-case        ::= id ('(' type ')')?
+record-decl         ::= 'record' id '{' fields '}'
+fields              ::= named-type (',' named-type)* ','?
+flags-decl          ::= 'flags' id '{' ids '}'
+ids                 ::= id (',' id)* ','?
+enum-decl           ::= 'enum' id '{' ids '}'
+type-alias          ::= 'type' id '=' (func-type | type) ';'
+func-type-ref       ::= func-type | id
+func-type           ::= '(' params? ')' ('->' results)?
+params              ::= named-type (',' named-type)* ','?
+results             ::= type
+                      | '(' named-type (',' named-type)* ','? ')'
+named-type          ::= id ':' type
+type                ::= u8
+                      | s8
+                      | u16
+                      | s16
+                      | u32
+                      | s32
+                      | u64
+                      | s64
+                      | float32
+                      | float64
+                      | char
+                      | bool
+                      | string
+                      | tuple
+                      | list
+                      | option
+                      | result
+                      | borrow
+                      | id
+tuple               ::= 'tuple' '<' type (',' type)* ','? '>'
+list                ::= 'list' '<' type '>'
+option              ::= 'option' '<' type '>'
+result              ::= 'result'
+                      | 'result' '<' type '>'
+                      | 'result' '<' '_' ',' type '>'
+                      | 'result' '<' type ',' type '>'
+borrow              ::= 'borrow' '<' type '>'
+
+let-statement           ::= 'let' id '=' expr ';'
+expr                    ::= primary-expr postfix-expr*
+primary-expr            ::= new-expr | nested-expr | id
+new-expr                ::= 'new' package-name '{' instantiation-args '}'
+instantiation-args      ::= instantiation-arg (',' instantiation-arg)* (',' '...'?)?
+instantiation-arg       ::= named-instantiation-arg | id
+named-instantiation-arg ::= (id | string) ':' expr
+nested-expr             ::= '(' expr ')'
+postfix-expr            ::= access-expr | named-access-expr
+access-expr             ::= '.' id
+named-access-expr       ::= '[' string ']'
+
+export-statement        ::= 'export' expr ('with' string)? ';'
+
+id     ::= '%'?[a-z][a-z0-9]*('-'[a-z][a-z0-9]*)*
+string ::= '"' character-that-is-not-a-double-quote* '"'
+```
+
+Whitespace (may appear anywhere between tokens):
+
+```ebnf
+whitespace ::= ' ' | '\n' | '\r' | '\t' | comment
+comment    ::= '//' character-that-is-not-a-newline*
+             | '/*' any-unicode-character* '*/'
+```
+
+Note: block comments are allowed to be nested.

README.md

@@ -11,11 +11,8 @@ repository = { workspace = true }
 
 [dependencies]
 anyhow = { workspace = true }
-clap = { workspace = true }
-pest = { workspace = true }
-pest_derive = { workspace = true }
-pest-ast = { workspace = true }
-from-pest = { workspace = true }
+logos = { workspace = true }
+thiserror = { workspace = true }
 semver = { workspace = true }
 log = { workspace = true }
 indexmap = { workspace = true }
@@ -24,7 +21,9 @@ serde = { workspace = true }
 wasmparser = { workspace = true }
 wit-parser = { workspace = true }
 wit-component = { workspace = true }
+smallvec = { workspace = true }
 wat = { workspace = true, optional = true }
+owo-colors = { workspace = true }
 
 [features]
 default = ["wat"]