Merge pull request #1 from wilkersonrdevon/feature/title-screen

Adds title screen section to tutorial

Author: Les-Wet

unbricked/title-screen/input.asm

@@ -0,0 +1,47 @@
+; This is a simplified version of pads.z80 by PinoBatch for use in gb-asm-tutorial
+; All labels are intentionally not exported to avoid confusing the reader with unfamiliar syntax.
+; Once linking is introduced in part 3, a new, exported version of this file will be provided.
+
+INCLUDE "../hardware.inc"
+
+SECTION "Input Variables", WRAM0
+wCurKeys:: db
+wNewKeys:: db
+
+SECTION "UpdateKeys", ROM0
+
+UpdateKeys::
+  ; Poll half the controller
+  ld a, P1F_GET_BTN
+  call .onenibble
+  ld b, a ; B7-4 = 1; B3-0 = unpressed buttons
+
+  ; Poll the other half
+  ld a, P1F_GET_DPAD
+  call .onenibble
+  swap a ; A3-0 = unpressed directions; A7-4 = 1
+  xor a, b ; A = pressed buttons + directions
+  ld b, a ; B = pressed buttons + directions
+
+  ; And release the controller
+  ld a, P1F_GET_NONE
+  ldh [rP1], a
+
+  ; Combine with previous wCurKeys to make wNewKeys
+  ld a, [wCurKeys]
+  xor a, b ; A = keys that changed state
+  and a, b ; A = keys that changed to pressed
+  ld [wNewKeys], a
+  ld a, b
+  ld [wCurKeys], a
+  ret
+
+.onenibble
+  ldh [rP1], a ; switch the key matrix
+  call .knownret ; burn 10 cycles calling a known ret
+  ldh a, [rP1] ; ignore value while waiting for the key matrix to settle
+  ldh a, [rP1]
+  ldh a, [rP1] ; this read counts
+  or a, $F0 ; A7-4 = 1; A3-0 = unpressed keys
+.knownret
+  ret