docs: add example to create dedicate hosts and host group

Author: edersonbrilhante

examples/dedicated-mac-hosts/README.md

@@ -0,0 +1,44 @@
+<!-- BEGIN_TF_DOCS -->
+## Requirements
+
+| Name | Version |
+|------|---------|
+| <a name="requirement_terraform"></a> [terraform](#requirement\_terraform) | ~> 1.11 |
+| <a name="requirement_aws"></a> [aws](#requirement\_aws) | ~> 6.0 |
+
+## Providers
+
+| Name | Version |
+|------|---------|
+| <a name="provider_aws"></a> [aws](#provider\_aws) | 6.27.0 |
+
+## Modules
+
+No modules.
+
+## Resources
+
+| Name | Type |
+|------|------|
+| [aws_ec2_host.mac_dedicated_host](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/ec2_host) | resource |
+| [aws_licensemanager_license_configuration.mac_dedicated_host_license_configuration](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/licensemanager_license_configuration) | resource |
+| [aws_resourcegroups_group.mac_host_group](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/resourcegroups_group) | resource |
+| [aws_resourcegroups_resource.mac_host_membership](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/resourcegroups_resource) | resource |
+
+## Inputs
+
+| Name | Description | Type | Default | Required |
+|------|-------------|------|---------|:--------:|
+| <a name="input_aws_profile"></a> [aws\_profile](#input\_aws\_profile) | AWS profile (i.e., generated via 'sl aws session generate') to use. | `string` | n/a | yes |
+| <a name="input_aws_region"></a> [aws\_region](#input\_aws\_region) | Default AWS region. | `string` | n/a | yes |
+| <a name="input_default_tags"></a> [default\_tags](#input\_default\_tags) | A map of tags to apply to resources. | `map(string)` | n/a | yes |
+| <a name="input_host_groups"></a> [host\_groups](#input\_host\_groups) | Map of host groups, each with a name, host instance type, and a list of hosts (name + AZ). | <pre>map(object({<br/>    name               = string<br/>    host_instance_type = string<br/>    hosts = list(object({<br/>      name              = string<br/>      availability_zone = string<br/>    }))<br/>  }))</pre> | n/a | yes |
+| <a name="input_tags"></a> [tags](#input\_tags) | A map of tags to apply to resources. | `map(string)` | n/a | yes |
+
+## Outputs
+
+| Name | Description |
+|------|-------------|
+| <a name="output_license_specification_arn"></a> [license\_specification\_arn](#output\_license\_specification\_arn) | ARN of the License Manager configuration used for Mac dedicated hosts. |
+| <a name="output_resource_group_arns"></a> [resource\_group\_arns](#output\_resource\_group\_arns) | Map of resource group names to their ARNs. |
+<!-- END_TF_DOCS -->

examples/dedicated-mac-hosts/main.tf

@@ -0,0 +1,105 @@
+locals {
+
+  environment = var.environment != null ? var.environment : "default"
+  aws_region  = var.aws_region
+
+  # Flatten host_groups into a map of individual host definitions keyed by
+  # "groupKey-hostName" so we can create one aws_ec2_host per host.
+  mac_dedicated_hosts = merge([
+    for group_key, group in var.host_groups : {
+      for host in group.hosts :
+      "${group_key}-${host.name}" => {
+        instance_type     = group.host_instance_type
+        availability_zone = host.availability_zone
+        group_name        = group.name
+        host_name         = host.name
+      }
+    }
+  ]...)
+}
+
+resource "aws_ec2_host" "mac_dedicated_host" {
+  for_each = local.mac_dedicated_hosts
+
+  instance_type     = each.value.instance_type
+  availability_zone = each.value.availability_zone
+  auto_placement    = "on"
+
+  tags = {
+    "Name"      = each.value.host_name
+    "HostGroup" = each.value.group_name
+  }
+}
+
+resource "aws_resourcegroups_group" "mac_host_group" {
+  for_each = { for _, group in var.host_groups : group.name => group }
+
+  name = each.value.name
+
+  configuration {
+    type = "AWS::EC2::HostManagement"
+
+    parameters {
+      name   = "any-host-based-license-configuration"
+      values = ["true"]
+    }
+
+    parameters {
+      name = "auto-allocate-host"
+      values = [
+        "false",
+      ]
+    }
+    parameters {
+      name = "auto-host-recovery"
+      values = [
+        "false",
+      ]
+    }
+    parameters {
+      name = "auto-release-host"
+      values = [
+        "false",
+      ]
+    }
+  }
+
+  configuration {
+    type = "AWS::ResourceGroups::Generic"
+    parameters {
+      name = "allowed-resource-types"
+      values = [
+        "AWS::EC2::Host",
+      ]
+    }
+
+    parameters {
+      name = "deletion-protection"
+      values = [
+        "UNLESS_EMPTY",
+      ]
+    }
+  }
+
+  tags = {
+    "Name" = each.value.name
+  }
+}
+
+resource "aws_resourcegroups_resource" "mac_host_membership" {
+  for_each = local.mac_dedicated_hosts
+
+  group_arn    = aws_resourcegroups_group.mac_host_group[each.value.group_name].arn
+  resource_arn = aws_ec2_host.mac_dedicated_host[each.key].arn
+}
+
+
+resource "aws_licensemanager_license_configuration" "mac_dedicated_host_license_configuration" {
+  name                  = "mac-dedicated-host-license-configuration"
+  description           = "Mac dedicated host license configuration"
+  license_counting_type = "Socket"
+
+  tags = {
+    "Name" = each.value.name
+  }
+}

examples/dedicated-mac-hosts/outputs.tf

@@ -0,0 +1,12 @@
+output "resource_group_arns" {
+  description = "Map of resource group names to their ARNs."
+  value = {
+    for k, rg in aws_resourcegroups_group.mac_host_group :
+    rg.name => rg.arn
+  }
+}
+
+output "license_specification_arn" {
+  description = "ARN of the License Manager configuration used for Mac dedicated hosts."
+  value       = aws_licensemanager_license_configuration.mac_dedicated_host_license_configuration.arn
+}

examples/dedicated-mac-hosts/providers.tf

@@ -0,0 +1,9 @@
+provider "aws" {
+  region = local.aws_region
+
+  default_tags {
+    tags = {
+      Example = local.environment
+    }
+  }
+}

examples/dedicated-mac-hosts/variables.tf

@@ -0,0 +1,23 @@
+variable "aws_region" {
+  description = "AWS region."
+  type        = string
+}
+
+variable "environment" {
+  description = "Environment name, used as prefix."
+
+  type    = string
+  default = null
+}
+
+variable "host_groups" {
+  description = "Map of host groups, each with a name, host instance type, and a list of hosts (name + AZ)."
+  type = map(object({
+    name               = string
+    host_instance_type = string
+    hosts = list(object({
+      name              = string
+      availability_zone = string
+    }))
+  }))
+}

examples/dedicated-mac-hosts/versions.tf

@@ -0,0 +1,10 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = ">= 6.21"
+    }
+  }
+
+  required_version = ">= 1.3.0"
+}