Finalize firs draft of Rule 6-2-3

Author: MichaelRFairhurst

change_notes/2026-04-19-refactor-nested-anonymous-namespace-logic.md

@@ -0,0 +1,3 @@
+ - All queries using `Linkage.qll`:
+   - The logic for determining whether a namespace is within an anonymous namespace, directly or indirectly, has been refactored.
+   - No visible change in behavior or performance is expected.

cpp/common/src/codingstandards/cpp/Linkage.qll

@@ -17,7 +17,7 @@ private predicate isSpecificationVariable(Variable v) {
 /** Holds if `elem` has internal linkage. */
 predicate hasInternalLinkage(Element elem) {
   // An unnamed namespace or a namespace declared directly or indirectly within an unnamed namespace has internal linkage
-  directlyOrIndirectlyUnnnamedNamespace(elem)
+  elem instanceof WithinAnonymousNamespace
   or
   exists(Declaration decl | decl = elem |
     // A name having namespace scope has internal linkage if it is the name of
@@ -46,7 +46,7 @@ predicate hasInternalLinkage(Element elem) {
       )
     )
     or
-    directlyOrIndirectlyUnnnamedNamespace(decl.getNamespace()) and
+    decl.getNamespace() instanceof WithinAnonymousNamespace and
     inheritsLinkageOfNamespace(decl.getNamespace(), decl)
     or
     exists(Class klass |
@@ -59,12 +59,12 @@ predicate hasInternalLinkage(Element elem) {
 /** Holds if `elem` has external linkage. */
 predicate hasExternalLinkage(Element elem) {
   elem instanceof Namespace and
-  not directlyOrIndirectlyUnnnamedNamespace(elem)
+  not elem instanceof WithinAnonymousNamespace
   or
   not hasInternalLinkage(elem) and
   exists(Declaration decl | decl = elem |
     // A name having namespace scope that has not been given internal linkage above has the same linkage as the enclosing namespace if it is the name of
-    not directlyOrIndirectlyUnnnamedNamespace(decl.getNamespace()) and
+    not decl.getNamespace() instanceof WithinAnonymousNamespace and
     inheritsLinkageOfNamespace(decl.getNamespace(), decl)
     or
     exists(Class klass |
@@ -74,11 +74,11 @@ predicate hasExternalLinkage(Element elem) {
   )
 }
 
-private predicate directlyOrIndirectlyUnnnamedNamespace(Namespace ns) {
-  exists(Namespace anonymous |
-    anonymous.isAnonymous() and
-    ns = anonymous.getAChildNamespace*()
-  )
+/**
+ * A `Namespace` that is anonymous or indirectly contained within an unnamed namespace.
+ */
+class WithinAnonymousNamespace extends Namespace {
+  WithinAnonymousNamespace() { getParentNamespace*().isAnonymous() }
 }
 
 private predicate hasLinkageOfTypedef(TypedefType typedef, Element decl) {

cpp/common/src/codingstandards/cpp/exclusions/cpp/Declarations8.qll

@@ -5,7 +5,8 @@ import codingstandards.cpp.exclusions.RuleMetadata
 
 newtype Declarations8Query =
   TSourceCodeImplementedOnlyOnceQuery() or
-  TTemplateSpecializationWrongLocationQuery()
+  TTemplateSpecializationWrongLocationQuery() or
+  TDuplicateTypeDefinitionsQuery()
 
 predicate isDeclarations8QueryMetadata(Query query, string queryId, string ruleId, string category) {
   query =
@@ -25,6 +26,15 @@ predicate isDeclarations8QueryMetadata(Query query, string queryId, string ruleI
     "cpp/misra/template-specialization-wrong-location" and
   ruleId = "RULE-6-2-3" and
   category = "required"
+  or
+  query =
+    // `Query` instance for the `duplicateTypeDefinitions` query
+    Declarations8Package::duplicateTypeDefinitionsQuery() and
+  queryId =
+    // `@id` for the `duplicateTypeDefinitions` query
+    "cpp/misra/duplicate-type-definitions" and
+  ruleId = "RULE-6-2-3" and
+  category = "required"
 }
 
 module Declarations8Package {
@@ -41,4 +51,11 @@ module Declarations8Package {
       // `Query` type for `templateSpecializationWrongLocation` query
       TQueryCPP(TDeclarations8PackageQuery(TTemplateSpecializationWrongLocationQuery()))
   }
+
+  Query duplicateTypeDefinitionsQuery() {
+    //autogenerate `Query` type
+    result =
+      // `Query` type for `duplicateTypeDefinitions` query
+      TQueryCPP(TDeclarations8PackageQuery(TDuplicateTypeDefinitionsQuery()))
+  }
 }

cpp/misra/src/rules/RULE-6-2-3/DuplicateTypeDefinitions.ql

@@ -0,0 +1,41 @@
+/**
+ * @id cpp/misra/duplicate-type-definitions
+ * @name RULE-6-2-3: RULE-6-2-3: Duplicate type definitions across files
+ * @description Defining a type with the same fully qualified name in multiple files increases the
+ *              risk of ODR violations and undefined behavior.
+ * @kind problem
+ * @precision very-high
+ * @problem.severity error
+ * @tags external/misra/id/rule-6-2-3
+ *       correctness
+ *       maintainability
+ *       scope/system
+ *       external/misra/enforcement/decidable
+ *       external/misra/obligation/required
+ */
+
+import cpp
+import codingstandards.cpp.misra
+import codingstandards.cpp.Linkage
+
+class UserTypeDefinition extends TypeDeclarationEntry {
+  UserTypeDefinition() {
+    (isDefinition() or getDeclaration() instanceof TypedefType) and
+    not getDeclaration().(Class).isAnonymous() and
+    not getDeclaration().(Union).isAnonymous() and
+    not getDeclaration().(Enum).isAnonymous() and
+    not getDeclaration() instanceof ClassTemplateSpecialization and
+    not getDeclaration().getNamespace() instanceof WithinAnonymousNamespace
+  }
+
+  UserType getUserType() { result = getDeclaration() }
+}
+
+from UserTypeDefinition t1, UserTypeDefinition t2
+where
+  not isExcluded(t1, Declarations8Package::duplicateTypeDefinitionsQuery()) and
+  t1.getUserType().getQualifiedName() = t2.getUserType().getQualifiedName() and
+  t1.getFile() != t2.getFile() and
+  t1.getFile().getAbsolutePath() < t2.getFile().getAbsolutePath() // Report only once per pair
+select t1, "Type '" + t1.getUserType().getQualifiedName() + "' is defined in files $@ and $@.", t1,
+  t1.getFile().getBaseName(), t2, t2.getFile().getBaseName()

cpp/misra/src/rules/RULE-6-2-3/SourceCodeImplementedOnlyOnce.ql

@@ -1,13 +1,14 @@
 /**
  * @id cpp/misra/source-code-implemented-only-once
  * @name RULE-6-2-3: The source code used to implement an entity shall appear only once
- * @description Implementing an entity in multiple source locations violates the one-definition rule
- *              and leads to undefined behavior.
+ * @description Implementing an entity in multiple source locations increases the risk of ODR
+ *              violations and undefined behavior.
  * @kind problem
  * @precision very-high
  * @problem.severity error
  * @tags external/misra/id/rule-6-2-3
  *       correctness
+ *       maintainability
  *       scope/system
  *       external/misra/enforcement/decidable
  *       external/misra/obligation/required

cpp/misra/src/rules/RULE-6-2-3/TemplateSpecializationWrongLocation.ql

@@ -8,6 +8,7 @@
  * @problem.severity error
  * @tags external/misra/id/rule-6-2-3
  *       correctness
+ *       maintainability
  *       scope/system
  *       external/misra/enforcement/decidable
  *       external/misra/obligation/required
@@ -24,7 +25,6 @@ predicate specializedWithFileDeclaredType(ClassTemplateSpecialization spec) {
   )
 }
 
-
 from ClassTemplateSpecialization spec, Class primaryTemplate, File primaryFile
 where
   not isExcluded(spec, Declarations8Package::templateSpecializationWrongLocationQuery()) and

cpp/misra/test/rules/RULE-6-2-3/DuplicateTypeDefinitions.expected

@@ -0,0 +1,9 @@
+| test.cpp:15:8:15:22 | definition of StructRedefined | Type 'StructRedefined' is defined in files $@ and $@. | test.cpp:15:8:15:22 | definition of StructRedefined | test.cpp | test2.cpp:16:8:16:22 | definition of StructRedefined | test2.cpp |
+| test.cpp:22:29:22:40 | definition of TplRedefined<T> | Type 'TplRedefined<T>' is defined in files $@ and $@. | test.cpp:22:29:22:40 | definition of TplRedefined<T> | test.cpp | test2.cpp:22:29:22:40 | definition of TplRedefined<T> | test2.cpp |
+| test.cpp:26:6:26:18 | definition of DuplicateEnum | Type 'DuplicateEnum' is defined in files $@ and $@. | test.cpp:26:6:26:18 | definition of DuplicateEnum | test.cpp | test2.cpp:25:6:25:18 | definition of DuplicateEnum | test2.cpp |
+| test.cpp:27:12:27:29 | definition of DuplicateEnumClass | Type 'DuplicateEnumClass' is defined in files $@ and $@. | test.cpp:27:12:27:29 | definition of DuplicateEnumClass | test.cpp | test2.cpp:26:12:26:29 | definition of DuplicateEnumClass | test2.cpp |
+| test.cpp:29:17:29:32 | declaration of DuplicateTypedef | Type 'DuplicateTypedef' is defined in files $@ and $@. | test.cpp:29:17:29:32 | declaration of DuplicateTypedef | test.cpp | test2.cpp:28:17:28:32 | declaration of DuplicateTypedef | test2.cpp |
+| test.cpp:30:7:30:20 | declaration of DuplicateUsing | Type 'DuplicateUsing' is defined in files $@ and $@. | test.cpp:30:7:30:20 | declaration of DuplicateUsing | test.cpp | test2.cpp:29:7:29:20 | declaration of DuplicateUsing | test2.cpp |
+| test.cpp:31:7:31:20 | definition of DuplicateUnion | Type 'DuplicateUnion' is defined in files $@ and $@. | test.cpp:31:7:31:20 | definition of DuplicateUnion | test.cpp | test2.cpp:30:7:30:20 | definition of DuplicateUnion | test2.cpp |
+| test.cpp:36:7:36:11 | definition of Outer | Type 'ns1::Outer' is defined in files $@ and $@. | test.cpp:36:7:36:11 | definition of Outer | test.cpp | test2.cpp:35:7:35:11 | definition of Outer | test2.cpp |
+| test.cpp:37:9:37:13 | definition of Inner | Type 'ns1::Outer::Inner' is defined in files $@ and $@. | test.cpp:37:9:37:13 | definition of Inner | test.cpp | test2.cpp:36:9:36:13 | definition of Inner | test2.cpp |

cpp/misra/test/rules/RULE-6-2-3/DuplicateTypeDefinitions.qlref

@@ -0,0 +1 @@
+rules/RULE-6-2-3/DuplicateTypeDefinitions.ql

cpp/misra/test/rules/RULE-6-2-3/test.cpp

@@ -12,6 +12,40 @@ inline void func_redeclared() {}      // COMPLIANT
 int16_t global_noninline = 0;       // COMPLIANT
 int func_noninline() { return 42; } // COMPLIANT
 
-#include "template.h"
+struct StructRedefined {};  // NON_COMPLIANT
+struct StructUnique {};     // COMPLIANT
+struct StructRedeclared {}; // COMPLIANT
+struct IncompleteStruct;    // COMPLIANT
+struct {
+} anonymousStruct1; // COMPLIANT
+
+template <typename T> class TplRedefined {};  // NON_COMPLIANT
+template <typename T> class TplUnique {};     // COMPLIANT
+template <typename T> class TplRedeclared {}; // COMPLIANT
+
+enum DuplicateEnum {};            // NON_COMPLIANT
+enum class DuplicateEnumClass {}; // NON_COMPLIANT
+enum {} anonymousEnum1;           // COMPLIANT
+typedef int16_t DuplicateTypedef; // NON_COMPLIANT
+using DuplicateUsing = int16_t;   // NON_COMPLIANT
+union DuplicateUnion {};          // NON_COMPLIANT
+union {
+} anonymousUnion1; // COMPLIANT
+
+namespace ns1 {
+class Outer {     // NON_COMPLIANT
+  class Inner {}; // NON_COMPLIANT
+};
+
+namespace {
+class AnonymousClass {}; // COMPLIANT
+} // namespace
+} // namespace ns1
+
+void f() {
+  auto x = []() { return 42; }; // COMPLIANT
+}
+
 #include "compliant_specialization.h"
 #include "noncompliant_specialization.h"
+#include "template.h"

cpp/misra/test/rules/RULE-6-2-3/test2.cpp

@@ -1,3 +1,6 @@
+// Note: the COMPLIANT/NON_COMPLIANT comments are here for documentary purposes;
+// we do not expect alerts in this file. These should be flagged in `test.cpp`.
+
 #include <cstdint>
 
 inline int16_t global_redefined = 0;     // NON_COMPLIANT[False negative]
@@ -8,4 +11,36 @@ inline void func_redeclared();           // COMPLIANT
 // Violates our implementation of 6.2.1, but legal in our implementation
 // of 6.2.3
 int16_t global_noninline = 0;       // COMPLIANT
-int func_noninline() { return 42; } // COMPLIANT
+int func_noninline() { return 42; } // COMPLIANT
+
+struct StructRedefined {}; // NON_COMPLIANT
+struct StructRedeclared;   // COMPLIANT
+struct IncompleteStruct;   // COMPLIANT
+struct {
+} anonymousStruct2; // COMPLIANT
+
+template <typename T> class TplRedefined {}; // NON_COMPLIANT
+template <typename T> class TplRedeclared;   // COMPLIANT
+
+enum DuplicateEnum {};            // NON_COMPLIANT
+enum class DuplicateEnumClass {}; // NON_COMPLIANT
+enum {} anonymousEnum1;           // COMPLIANT
+typedef int16_t DuplicateTypedef; // NON_COMPLIANT
+using DuplicateUsing = int16_t;   // NON_COMPLIANT
+union DuplicateUnion {};          // NON_COMPLIANT
+union {
+} anonymousUnion2; // COMPLIANT
+
+namespace ns1 {
+class Outer {     // NON_COMPLIANT
+  class Inner {}; // NON_COMPLIANT
+};
+
+namespace {
+class AnonymousClass {}; // COMPLIANT
+} // namespace
+} // namespace ns1
+
+void f2() {
+  auto x = []() { return 42; }; // COMPLIANT
+}