QL for QL: generalise non-US spelling query

1. Catch common misspelling as well.
2. Also check names of classes, predicates, etc.

Author: nickrolfe

config/identical-files.json

@@ -550,5 +550,9 @@
   "HttpToFileAccessCustomizations JS/Ruby": [
     "javascript/ql/lib/semmle/javascript/security/dataflow/HttpToFileAccessCustomizations.qll",
     "ruby/ql/lib/codeql/ruby/security/HttpToFileAccessCustomizations.qll"
+  ],
+  "Typo database": [
+    "javascript/ql/src/Expressions/TypoDatabase.qll",
+    "ql/ql/src/codeql_ql/style/TypoDatabase.qll"
   ]
 }

ql/ql/src/codeql_ql/style/AcronymsShouldBeCamelCaseQuery.qll

@@ -1,35 +1,5 @@
 import ql
-
-/**
- * Gets the name for a `node` that defines something in a QL program.
- * E.g. a predicate, class, or module definition.
- */
-string getName(AstNode node, string kind) {
-  result = node.(Class).getName() and kind = "class"
-  or
-  // not including CharPreds or db relations. The remaining are: classlessPredicate, classPredicate, newTypeBranch.
-  result = node.(ClasslessPredicate).getName() and
-  kind = "classlessPredicate"
-  or
-  result = node.(ClassPredicate).getName() and
-  kind = "classPredicate"
-  or
-  result = node.(NewTypeBranch).getName() and
-  kind = "newtypeBranch"
-  or
-  result = node.(NewType).getName() and
-  kind = "newtype"
-  or
-  result = node.(VarDecl).getName() and
-  kind = "variable" and
-  not node = any(FieldDecl f).getVarDecl()
-  or
-  result = node.(FieldDecl).getName() and kind = "field"
-  or
-  result = node.(Module).getName() and kind = "module"
-  or
-  result = node.(Import).importedAs() and kind = "import"
-}
+private import NodeName
 
 string prettyPluralKind(string kind) {
   kind = "class" and result = "classes"

ql/ql/src/codeql_ql/style/MisspellingQuery.qll

@@ -0,0 +1,64 @@
+import ql
+private import NodeName
+private import TypoDatabase
+
+predicate misspelling(string wrong, string right, string mistake) {
+  mistake = "common misspelling" and
+  typos(wrong, right)
+  or
+  mistake = "non-US spelling" and
+  non_us_spelling(wrong, right)
+}
+
+/**
+ * Holds if `word` is an acceptable spelling that would otherwise be considered
+ * a mistake by the typo database.
+ */
+predicate isAllowed(string word) {
+  word =
+    [
+      "asign", // 'sign of a', not 'assign'
+      "larg", // 'left argument', not 'large'
+      "nto", // some comments refer to the variable `nTo`
+      "thn" // deliberate misspelling of 'then' to avoid using a keyword
+    ]
+}
+
+predicate non_us_spelling(string wrong, string right) {
+  exists(string s |
+    wrong = s.splitAt("/", 0) and
+    right = s.splitAt("/", 1) and
+    s =
+      [
+        "colour/color", "authorise/authorize", "authorises/authorizes", "authorised/authorized",
+        "analyse/analyze", "analysed/analyzed", "behaviour/behavior", "modelling/modeling",
+        "modelled/modeled"
+      ]
+  )
+}
+
+/**
+ * Gets a word in the camel-case string `s`. For example, if `s` is
+ * `"getFooBar"`, it returns `"get"`, `"Foo"`, and `"Bar"`.
+ */
+bindingset[s]
+string getACamelCaseWord(string s) { result = s.regexpFind("(^[a-z]+)|([A-Z][a-z]+)", _, _) }
+
+bindingset[s]
+string getACommentWord(string s) { result = s.regexpFind("\\b\\w+\\b", _, _) }
+
+string getAWord(AstNode node, string kind) {
+  result = getACommentWord(node.(QLDoc).getContents()).toLowerCase() and
+  kind = "QLDoc comment"
+  or
+  exists(string nodeKind |
+    result = getACamelCaseWord(getName(node, nodeKind)).toLowerCase() and
+    kind = nodeKind + " name"
+  )
+}
+
+predicate misspelled_element(AstNode node, string kind, string wrong, string right, string mistake) {
+  wrong = getAWord(node, kind) and
+  misspelling(wrong, right, mistake) and
+  not isAllowed(wrong)
+}

ql/ql/src/codeql_ql/style/NodeName.qll

@@ -0,0 +1,32 @@
+import ql
+
+/**
+ * Gets the name for a `node` that defines something in a QL program.
+ * E.g. a predicate, class, or module definition.
+ */
+string getName(AstNode node, string kind) {
+  result = node.(Class).getName() and kind = "class"
+  or
+  // not including CharPreds or db relations. The remaining are: classlessPredicate, classPredicate, newTypeBranch.
+  result = node.(ClasslessPredicate).getName() and
+  kind = "classlessPredicate"
+  or
+  result = node.(ClassPredicate).getName() and
+  kind = "classPredicate"
+  or
+  result = node.(NewTypeBranch).getName() and
+  kind = "newtypeBranch"
+  or
+  result = node.(NewType).getName() and
+  kind = "newtype"
+  or
+  result = node.(VarDecl).getName() and
+  kind = "variable" and
+  not node = any(FieldDecl f).getVarDecl()
+  or
+  result = node.(FieldDecl).getName() and kind = "field"
+  or
+  result = node.(Module).getName() and kind = "module"
+  or
+  result = node.(Import).importedAs() and kind = "import"
+}