C#: Include type parameters when printing MaD rows with generics

Author: hvitved

csharp/ql/lib/semmle/code/csharp/commons/QualifiedName.qll

@@ -160,30 +160,30 @@ module QualifiedName<QualifiedNameInputSig Input> {
   }
 
   /**
-   * Holds if member `m` has name `name` and is defined in type `type`
+   * Holds if declaration `d` has name `name` and is defined in type `type`
    * with namespace `namespace`.
    */
-  predicate hasQualifiedName(Member m, string namespace, string type, string name) {
-    m =
-      any(ConstructedMethod cm |
-        hasQualifiedName(cm.getDeclaringType(), namespace, type) and
-        name = cm.getUndecoratedName() + "<" + getTypeArgumentsQualifiedNames(cm) + ">"
-      )
-    or
-    m =
-      any(UnboundGenericMethod ugm |
-        hasQualifiedName(ugm.getDeclaringType(), namespace, type) and
-        name = ugm.getUndecoratedName() + Input::getUnboundGenericSuffix(ugm)
-      )
-    or
-    not m instanceof ConstructedMethod and
-    not m instanceof UnboundGenericMethod and
-    hasQualifiedName(m.getDeclaringType(), namespace, type) and
+  predicate hasQualifiedName(Declaration d, string namespace, string type, string name) {
+    hasQualifiedName(d.getDeclaringType(), namespace, type) and
     (
-      name = m.(Operator).getFunctionName()
+      d =
+        any(ConstructedMethod cm |
+          name = cm.getUndecoratedName() + "<" + getTypeArgumentsQualifiedNames(cm) + ">"
+        )
       or
-      not m instanceof Operator and
-      name = m.getName()
+      d =
+        any(UnboundGenericMethod ugm |
+          name = ugm.getUndecoratedName() + Input::getUnboundGenericSuffix(ugm)
+        )
+      or
+      not d instanceof ConstructedMethod and
+      not d instanceof UnboundGenericMethod and
+      (
+        name = d.(Operator).getFunctionName()
+        or
+        not d instanceof Operator and
+        name = d.getName()
+      )
     )
   }
 }

csharp/ql/lib/semmle/code/csharp/dataflow/internal/DataFlowPrivate.qll

@@ -2488,68 +2488,3 @@ abstract class SyntheticField extends string {
  * Holds if the the content `c` is a container.
  */
 predicate containerContent(DataFlow::Content c) { c instanceof DataFlow::ElementContent }
-
-/** Gets the string representation of the parameters of `c`. */
-string parameterQualifiedTypeNamesToString(DotNet::Callable c) {
-  result =
-    concat(Parameter p, int i |
-      p = c.getParameter(i)
-    |
-      p.getType().getQualifiedName(), "," order by i
-    )
-}
-
-/**
- * A module containing predicates related to generating MaD models.
- */
-module Csv {
-  /** Holds if the summary should apply for all overrides of `c`. */
-  predicate isBaseCallableOrPrototype(DotNet::Callable c) {
-    c.getDeclaringType() instanceof Interface
-    or
-    exists(Modifiable m | m = [c.(Modifiable), c.(Accessor).getDeclaration()] |
-      m.isAbstract()
-      or
-      c.getDeclaringType().(Modifiable).isAbstract() and m.(Virtualizable).isVirtual()
-    )
-  }
-
-  /** Gets a string representing whether the summary should apply for all overrides of `c`. */
-  private string getCallableOverride(DotNet::Callable c) {
-    if isBaseCallableOrPrototype(c) then result = "true" else result = "false"
-  }
-
-  private predicate partialModel(
-    DotNet::Callable c, string namespace, string type, string name, string parameters
-  ) {
-    c.getDeclaringType().hasQualifiedName(namespace, type) and
-    c.hasQualifiedName(_, name) and
-    parameters = "(" + parameterQualifiedTypeNamesToString(c) + ")"
-  }
-
-  /** Computes the first 6 columns for positive CSV rows of `c`. */
-  string asPartialModel(DotNet::Callable c) {
-    exists(string namespace, string type, string name, string parameters |
-      partialModel(c, namespace, type, name, parameters) and
-      result =
-        namespace + ";" //
-          + type + ";" //
-          + getCallableOverride(c) + ";" //
-          + name + ";" //
-          + parameters + ";" //
-          + /* ext + */ ";" //
-    )
-  }
-
-  /** Computes the first 4 columns for neutral CSV rows of `c`. */
-  string asPartialNeutralModel(DotNet::Callable c) {
-    exists(string namespace, string type, string name, string parameters |
-      partialModel(c, namespace, type, name, parameters) and
-      result =
-        namespace + ";" //
-          + type + ";" //
-          + name + ";" //
-          + parameters + ";" //
-    )
-  }
-}

csharp/ql/lib/semmle/code/csharp/dataflow/internal/ExternalFlow.qll

@@ -95,6 +95,7 @@ private import DataFlowPublic
 private import FlowSummaryImpl::Public
 private import FlowSummaryImpl::Private::External
 private import FlowSummaryImplSpecific
+private import semmle.code.csharp.commons.QualifiedName
 private import codeql.mad.ModelValidation as SharedModelVal
 
 private predicate relevantNamespace(string namespace) {
@@ -449,3 +450,76 @@ private module Cached {
 }
 
 import Cached
+
+/** Holds if the summary should apply for all overrides of `c`. */
+predicate isBaseCallableOrPrototype(UnboundCallable c) {
+  c.getDeclaringType() instanceof Interface
+  or
+  exists(Modifiable m | m = [c.(Modifiable), c.(Accessor).getDeclaration()] |
+    m.isAbstract()
+    or
+    c.getDeclaringType().(Modifiable).isAbstract() and m.(Virtualizable).isVirtual()
+  )
+}
+
+/** Gets a string representing whether the summary should apply for all overrides of `c`. */
+private string getCallableOverride(UnboundCallable c) {
+  if isBaseCallableOrPrototype(c) then result = "true" else result = "false"
+}
+
+private module QualifiedNameInput implements QualifiedNameInputSig {
+  string getUnboundGenericSuffix(UnboundGeneric ug) {
+    result =
+      "<" + strictconcat(int i, string s | s = ug.getTypeParameter(i).getName() | s, "," order by i)
+        + ">"
+  }
+}
+
+private module QN = QualifiedName<QualifiedNameInput>;
+
+pragma[nomagic]
+private string parameterQualifiedType(Parameter p) {
+  exists(string qualifier, string name |
+    QN::hasQualifiedName(p.getType(), qualifier, name) and
+    result = getQualifiedName(qualifier, name)
+  )
+}
+
+/** Gets the string representation of the parameters of `c`. */
+string parameterQualifiedTypeNamesToString(Callable c) {
+  result =
+    concat(int i, string s | s = parameterQualifiedType(c.getParameter(i)) | s, "," order by i)
+}
+
+private predicate partialModel(
+  UnboundCallable c, string namespace, string type, string name, string parameters
+) {
+  QN::hasQualifiedName(c, namespace, type, name) and
+  parameters = "(" + parameterQualifiedTypeNamesToString(c) + ")"
+}
+
+/** Computes the first 6 columns for positive CSV rows of `c`. */
+string asPartialModel(UnboundCallable c) {
+  exists(string namespace, string type, string name, string parameters |
+    partialModel(c, namespace, type, name, parameters) and
+    result =
+      namespace + ";" //
+        + type + ";" //
+        + getCallableOverride(c) + ";" //
+        + name + ";" //
+        + parameters + ";" //
+        + /* ext + */ ";" //
+  )
+}
+
+/** Computes the first 4 columns for neutral CSV rows of `c`. */
+string asPartialNeutralModel(UnboundCallable c) {
+  exists(string namespace, string type, string name, string parameters |
+    partialModel(c, namespace, type, name, parameters) and
+    result =
+      namespace + ";" //
+        + type + ";" //
+        + name + ";" //
+        + parameters + ";" //
+  )
+}

csharp/ql/src/utils/modeleditor/ModelEditor.qll

@@ -2,8 +2,8 @@
 
 private import csharp
 private import semmle.code.csharp.dataflow.FlowSummary
-private import semmle.code.csharp.dataflow.internal.DataFlowPrivate
 private import semmle.code.csharp.dataflow.internal.FlowSummaryImpl as FlowSummaryImpl
+private import semmle.code.csharp.dataflow.internal.ExternalFlow
 private import semmle.code.csharp.frameworks.Test
 private import Telemetry.TestLibrary
 

csharp/ql/src/utils/modelgenerator/internal/CaptureModelsSpecific.qll

@@ -65,9 +65,9 @@ class TargetApiSpecific extends DotNet::Callable {
   }
 }
 
-predicate asPartialModel = DataFlowPrivate::Csv::asPartialModel/1;
+predicate asPartialModel = ExternalFlow::asPartialModel/1;
 
-predicate asPartialNeutralModel = DataFlowPrivate::Csv::asPartialNeutralModel/1;
+predicate asPartialNeutralModel = ExternalFlow::asPartialNeutralModel/1;
 
 /**
  * Holds if `t` is a type that is generally used for bulk data in collection types.