Ruby: configsig rb/clear-text-storage-sensitive-data

Author: alexrford

ruby/ql/lib/codeql/ruby/security/CleartextStorageQuery.qll

@@ -2,32 +2,50 @@
  * Provides a taint-tracking configuration for "Clear-text storage of sensitive information".
  *
  * Note, for performance reasons: only import this file if
- * `Configuration` is needed, otherwise `CleartextStorageCustomizations` should be
- * imported instead.
+ * `CleartextStorageFlow` is needed, otherwise
+ * `CleartextStorageCustomizations` should be imported instead.
  */
 
 private import codeql.ruby.AST
 private import codeql.ruby.DataFlow
 private import codeql.ruby.TaintTracking
-private import CleartextStorageCustomizations::CleartextStorage as CleartextStorage
+private import CleartextStorageCustomizations::CleartextStorage as CS
 
 /**
  * A taint-tracking configuration for detecting "Clear-text storage of sensitive information".
+ * DEPRECATED: Use `CleartextStorageFlow` instead
  */
-class Configuration extends TaintTracking::Configuration {
+deprecated class Configuration extends TaintTracking::Configuration {
   Configuration() { this = "CleartextStorage" }
 
-  override predicate isSource(DataFlow::Node source) { source instanceof CleartextStorage::Source }
+  override predicate isSource(DataFlow::Node source) { source instanceof CS::Source }
 
-  override predicate isSink(DataFlow::Node sink) { sink instanceof CleartextStorage::Sink }
+  override predicate isSink(DataFlow::Node sink) { sink instanceof CS::Sink }
 
   override predicate isSanitizer(DataFlow::Node node) {
     super.isSanitizer(node)
     or
-    node instanceof CleartextStorage::Sanitizer
+    node instanceof CS::Sanitizer
   }
 
   override predicate isAdditionalTaintStep(DataFlow::Node nodeFrom, DataFlow::Node nodeTo) {
-    CleartextStorage::isAdditionalTaintStep(nodeFrom, nodeTo)
+    CS::isAdditionalTaintStep(nodeFrom, nodeTo)
   }
 }
+
+private module Config implements DataFlow::ConfigSig {
+  predicate isSource(DataFlow::Node source) { source instanceof CS::Source }
+
+  predicate isSink(DataFlow::Node sink) { sink instanceof CS::Sink }
+
+  predicate isBarrier(DataFlow::Node node) { node instanceof CS::Sanitizer }
+
+  predicate isAdditionalFlowStep(DataFlow::Node nodeFrom, DataFlow::Node nodeTo) {
+    CS::isAdditionalTaintStep(nodeFrom, nodeTo)
+  }
+}
+
+/**
+ * Taint-tracking for detecting "Clear-text storage of sensitive information".
+ */
+module CleartextStorageFlow = TaintTracking::Global<Config>;

ruby/ql/src/queries/security/cwe-312/CleartextStorage.ql

@@ -16,10 +16,9 @@
 import codeql.ruby.AST
 import codeql.ruby.security.CleartextStorageQuery
 import codeql.ruby.security.CleartextStorageCustomizations::CleartextStorage
-import codeql.ruby.DataFlow
-import DataFlow::PathGraph
+import CleartextStorageFlow::PathGraph
 
-from Configuration config, DataFlow::PathNode source, DataFlow::PathNode sink
-where config.hasFlowPath(source, sink)
+from CleartextStorageFlow::PathNode source, CleartextStorageFlow::PathNode sink
+where CleartextStorageFlow::flowPath(source, sink)
 select sink.getNode(), source, sink, "This stores sensitive data returned by $@ as clear text.",
   source.getNode(), source.getNode().(Source).describe()