JS: Switch from hasLocationInfo to Location

Author: asgerf

javascript/ql/lib/semmle/javascript/ApiGraphs.qll

@@ -501,16 +501,25 @@ module API {
     }
 
     /**
+     * Gets the location of this API node, if it corresponds to a program element with a source location.
+     */
+    final Location getLocation() { result = this.getInducingNode().getLocation() }
+
+    /**
+     * DEPRECATED: Use `getLocation().hasLocationInfo()` instead.
+     *
      * Holds if this node is located in file `path` between line `startline`, column `startcol`,
      * and line `endline`, column `endcol`.
      *
      * For nodes that do not have a meaningful location, `path` is the empty string and all other
      * parameters are zero.
      */
-    predicate hasLocationInfo(string path, int startline, int startcol, int endline, int endcol) {
-      this.getInducingNode().hasLocationInfo(path, startline, startcol, endline, endcol)
+    deprecated predicate hasLocationInfo(
+      string path, int startline, int startcol, int endline, int endcol
+    ) {
+      this.getLocation().hasLocationInfo(path, startline, startcol, endline, endcol)
       or
-      not exists(this.getInducingNode()) and
+      not exists(this.getLocation()) and
       path = "" and
       startline = 0 and
       startcol = 0 and

javascript/ql/lib/semmle/javascript/frameworks/data/ModelsAsData.qll

@@ -88,7 +88,7 @@ module ModelExport<ModelExportSig S> {
   private import codeql.mad.dynamic.GraphExport
   private import internal.ApiGraphModelsExport
 
-  private module GraphExportConfig implements GraphExportSig<API::Node> {
+  private module GraphExportConfig implements GraphExportSig<Location, API::Node> {
     predicate edge = Specific::apiGraphHasEdge/3;
 
     predicate shouldContain = S::shouldContain/1;

javascript/ql/lib/semmle/javascript/frameworks/data/internal/ApiGraphModelsExport.qll

@@ -65,7 +65,9 @@ signature predicate shouldContainTypeSig(string type);
  * Notice that the access path `Member[blah].Member[z]` consists of an access path generated from the API
  * graph, with pieces of the access path from the original type model appended to it.
  */
-module TypeGraphExport<GraphExportSig<API::Node> S, shouldContainTypeSig/1 shouldContainType> {
+module TypeGraphExport<
+  GraphExportSig<Specific::Location, API::Node> S, shouldContainTypeSig/1 shouldContainType>
+{
   /** Like `shouldContainType` but includes types that lead to `type` via type models. */
   private predicate shouldContainTypeEx(string type) {
     shouldContainType(type)
@@ -76,7 +78,7 @@ module TypeGraphExport<GraphExportSig<API::Node> S, shouldContainTypeSig/1 shoul
     )
   }
 
-  private module Config implements GraphExportSig<API::Node> {
+  private module Config implements GraphExportSig<Specific::Location, API::Node> {
     import S
 
     predicate shouldContain(API::Node node) {
@@ -93,7 +95,7 @@ module TypeGraphExport<GraphExportSig<API::Node> S, shouldContainTypeSig/1 shoul
     }
   }
 
-  private module ExportedGraph = GraphExport<API::Node, Config>;
+  private module ExportedGraph = GraphExport<Specific::Location, API::Node, Config>;
 
   import ExportedGraph
 

javascript/ql/lib/semmle/javascript/frameworks/data/internal/ApiGraphModelsSpecific.qll

@@ -27,6 +27,8 @@ module API = JS::API;
 
 import JS::DataFlow as DataFlow
 
+class Location = JS::Location;
+
 /**
  * Holds if `rawType` represents the JavaScript type `qualifiedName` from the given NPM `package`.
  *

shared/mad/codeql/mad/dynamic/GraphExport.qll

@@ -2,6 +2,8 @@
  * Contains predicates for converting an arbitrary graph to a set of `typeModel` rows.
  */
 
+private import codeql.util.Location
+
 /**
  * Concatenates two access paths, separating them by `.` unless one of them is empty.
  */
@@ -10,21 +12,20 @@ string join(string x, string y) {
   if x = "" or y = "" then result = x + y else result = x + "." + y
 }
 
-signature class NodeSig {
-  /**
-   * Holds if this node is located in file `path` between line `startline`, column `startcol`,
-   * and line `endline`, column `endcol`.
-   */
-  predicate hasLocationInfo(string path, int startline, int startcol, int endline, int endcol);
+private module WithLocation<LocationSig Location> {
+  signature class NodeSig {
+    /** Gets the location of this node if it has one. */
+    Location getLocation();
 
-  /** Gets a string representation of this node. */
-  string toString();
+    /** Gets a string representation of this node. */
+    string toString();
+  }
 }
 
 /**
  * Specifies a graph to export in `GraphExport`.
  */
-signature module GraphExportSig<NodeSig Node> {
+signature module GraphExportSig<LocationSig Location, WithLocation<Location>::NodeSig Node> {
   /**
    * Holds if an edge `pred -> succ` exist with the access path `path`.
    */
@@ -81,7 +82,9 @@ signature module GraphExportSig<NodeSig Node> {
 /**
  * Module for exporting an arbitrary graph as models-as-data rows.
  */
-module GraphExport<NodeSig Node, GraphExportSig<Node> S> {
+module GraphExport<
+  LocationSig Location, WithLocation<Location>::NodeSig Node, GraphExportSig<Location, Node> S>
+{
   private import S
 
   private Node getAnExposedNode() {
@@ -163,9 +166,10 @@ module GraphExport<NodeSig Node, GraphExportSig<Node> S> {
       node =
         rank[k](RelevantNode n, string path, int startline, int startcol, int endline, int endcol |
           isSyntheticallyNamedNode(n, prefixTypeName) and
-          n.hasLocationInfo(path, startline, startcol, endline, endcol)
+          n.getLocation().hasLocationInfo(path, startline, startcol, endline, endcol)
         |
           // Use location information for an arbitrary ordering
+          // TODO: improve support for nodes without a location, currently they can cause FNs
           n order by path, startline, startcol, endline, endcol
         ) and
       result = prefixTypeName + "~expr" + k

shared/mad/qlpack.yml

@@ -2,5 +2,6 @@ name: codeql/mad
 version: 0.2.14-dev
 groups: shared
 library: true
-dependencies: null
+dependencies:
+  codeql/util: ${workspace}
 warnOnImplicitThis: true