JS: Replace member edges with content edges

Author: asgerf

javascript/ql/lib/semmle/javascript/ApiGraphs.qll

@@ -1473,10 +1473,13 @@ module API {
     /** Gets the `member` edge label for member `m`. */
     bindingset[m]
     bindingset[result]
-    LabelMember member(string m) { result.getProperty() = m }
+    LabelContent member(string m) { result.getContent().asPropertyName() = m }
+
+    /** Gets the `content` edge label for content `c`. */
+    LabelContent content(Content c) { result.getContent() = c }
 
     /** Gets the `member` edge label for the unknown member. */
-    LabelUnknownMember unknownMember() { any() }
+    LabelContent unknownMember() { result.getContent().isUnknownArrayElement() }
 
     /**
      * Gets a property name referred to by the given dynamic property access,
@@ -1533,10 +1536,10 @@ module API {
     LabelForwardingFunction forwardingFunction() { any() }
 
     /** Gets the `promised` edge label connecting a promise to its contained value. */
-    LabelPromised promised() { any() }
+    LabelContent promised() { result.getContent() = MkPromiseValue() }
 
     /** Gets the `promisedError` edge label connecting a promise to its rejected value. */
-    LabelPromisedError promisedError() { any() }
+    LabelContent promisedError() { result.getContent() = MkPromiseError() }
 
     /** Gets the label for an edge leading from a value `D` to any class that has `D` as a decorator. */
     LabelDecoratedClass decoratedClass() { any() }
@@ -1550,6 +1553,7 @@ module API {
     /** Gets an entry-point label for the entry-point `e`. */
     LabelEntryPoint entryPoint(API::EntryPoint e) { result.getEntryPoint() = e }
 
+    private import semmle.javascript.dataflow.internal.Contents::Private
     private import LabelImpl
 
     private module LabelImpl {
@@ -1559,18 +1563,7 @@ module API {
           exists(Impl::MkModuleImport(mod))
         } or
         MkLabelInstance() or
-        MkLabelMember(string prop) {
-          exports(_, prop, _) or
-          exists(any(DataFlow::ClassNode c).getInstanceMethod(prop)) or
-          prop = "exports" or
-          prop = any(CanonicalName c).getName() or
-          prop = any(DataFlow::PropRef p).getPropertyName() or
-          exists(Impl::MkTypeUse(_, prop)) or
-          exists(any(Module m).getAnExportedValue(prop)) or
-          PreCallGraphStep::loadStep(_, _, prop) or
-          PreCallGraphStep::storeStep(_, _, prop)
-        } or
-        MkLabelUnknownMember() or
+        MkLabelContent(DataFlow::Content content) or
         MkLabelParameter(int i) {
           i =
             [0 .. max(int args |
@@ -1581,8 +1574,6 @@ module API {
         } or
         MkLabelReceiver() or
         MkLabelReturn() or
-        MkLabelPromised() or
-        MkLabelPromisedError() or
         MkLabelDecoratedClass() or
         MkLabelDecoratedMember() or
         MkLabelDecoratedParameter() or
@@ -1602,13 +1593,13 @@ module API {
       }
 
       /** A label that gets a promised value. */
-      class LabelPromised extends ApiLabel, MkLabelPromised {
-        override string toString() { result = "getPromised()" }
+      deprecated class LabelPromised extends ApiLabel {
+        LabelPromised() { this = MkLabelContent(MkPromiseValue()) }
       }
 
       /** A label that gets a rejected promise. */
-      class LabelPromisedError extends ApiLabel, MkLabelPromisedError {
-        override string toString() { result = "getPromisedError()" }
+      deprecated class LabelPromisedError extends ApiLabel {
+        LabelPromisedError() { this = MkLabelContent(MkPromiseError()) }
       }
 
       /** A label that gets the return value of a function. */
@@ -1634,23 +1625,36 @@ module API {
         override string toString() { result = "getInstance()" }
       }
 
+      /** A label for a content. */
+      class LabelContent extends ApiLabel, MkLabelContent {
+        private DataFlow::Content content;
+
+        LabelContent() { this = MkLabelContent(content) }
+
+        /** Gets the content associated with this label. */
+        DataFlow::Content getContent() { result = content }
+
+        override string toString() {
+          result = "getMember(\"" + content.asPropertyName() + "\")"
+          or
+          not exists(content.asPropertyName()) and
+          result = "getContent(" + content + ")"
+        }
+      }
+
       /** A label for the member named `prop`. */
-      class LabelMember extends ApiLabel, MkLabelMember {
-        string prop;
+      deprecated class LabelMember extends LabelContent {
+        private string prop;
 
-        LabelMember() { this = MkLabelMember(prop) }
+        LabelMember() { prop = this.getContent().asPropertyName() }
 
         /** Gets the property associated with this label. */
         string getProperty() { result = prop }
-
-        override string toString() { result = "getMember(\"" + prop + "\")" }
       }
 
       /** A label for a member with an unknown name. */
-      class LabelUnknownMember extends ApiLabel, MkLabelUnknownMember {
-        LabelUnknownMember() { this = MkLabelUnknownMember() }
-
-        override string toString() { result = "getUnknownMember()" }
+      deprecated class LabelUnknownMember extends LabelContent {
+        LabelUnknownMember() { this.getContent().isUnknownArrayElement() }
       }
 
       /** A label for parameter `i`. */

javascript/ql/lib/semmle/javascript/dataflow/internal/Contents.qll

@@ -57,6 +57,8 @@ module Private {
       this = getAPreciseArrayIndex().toString()
       or
       isAccessPathTokenPresent("Member", this)
+      or
+      this = ["exports", "default"] // needed by API graphs
     }
 
     /** Gets the array index corresponding to this property name. */