Make taint tracking tests use new API

Author: owen-mc

go/ql/test/library-tests/semmle/go/frameworks/Revel/test.ql

@@ -7,22 +7,22 @@ class Sink extends DataFlow::Node {
   }
 }
 
-class TestConfig extends TaintTracking::Configuration {
-  TestConfig() { this = "testconfig" }
+private module TestConfig implements DataFlow::ConfigSig {
+  predicate isSource(DataFlow::Node source) { source instanceof UntrustedFlowSource }
 
-  override predicate isSource(DataFlow::Node source) { source instanceof UntrustedFlowSource }
-
-  override predicate isSink(DataFlow::Node sink) { sink instanceof Sink }
+  predicate isSink(DataFlow::Node sink) { sink instanceof Sink }
 }
 
+private module TestFlow = TaintTracking::Global<TestConfig>;
+
 module MissingDataFlowTest implements TestSig {
   string getARelevantTag() { result = "noflow" }
 
   predicate hasActualResult(Location location, string element, string tag, string value) {
     tag = "noflow" and
     value = "" and
     exists(Sink sink |
-      not any(TestConfig c).hasFlow(_, sink) and
+      not TestFlow::flowTo(sink) and
       sink.hasLocationInfo(location.getFile().getAbsolutePath(), location.getStartLine(),
         location.getStartColumn(), location.getEndLine(), location.getEndColumn()) and
       element = sink.toString()

go/ql/test/library-tests/semmle/go/frameworks/StdlibTaintFlow/StdlibTaintFlow.ql

@@ -25,26 +25,24 @@ predicate callArgumentisSink(DataFlow::Node sink, DataFlow::CallNode call) {
   )
 }
 
-class FlowConf extends TaintTracking::Configuration {
-  FlowConf() { this = "FlowConf" }
+module Config implements DataFlow::ConfigSig {
+  predicate isSource(DataFlow::Node source) { callResultisSource(source, _) }
 
-  override predicate isSource(DataFlow::Node source) { callResultisSource(source, _) }
-
-  override predicate isSink(DataFlow::Node sink) { callArgumentisSink(sink, _) }
+  predicate isSink(DataFlow::Node sink) { callArgumentisSink(sink, _) }
 }
 
+module Flow = TaintTracking::Global<Config>;
+
 /**
  * True if the result of the provided sourceCall flows to the corresponding sink,
  * both marked by the same numeric first argument.
  */
 predicate flowsToSink(DataFlow::CallNode sourceCall) {
-  exists(
-    FlowConf cfg, DataFlow::PathNode source, DataFlow::PathNode sink, DataFlow::CallNode sinkCall
-  |
-    cfg.hasFlowPath(source, sink) and
+  exists(DataFlow::Node source, DataFlow::Node sink, DataFlow::CallNode sinkCall |
+    Flow::flow(source, sink) and
     (
-      callResultisSource(source.getNode(), sourceCall) and
-      callArgumentisSink(sink.getNode(), sinkCall) and
+      callResultisSource(source, sourceCall) and
+      callArgumentisSink(sink, sinkCall) and
       sourceCall.getArgument(0).getIntValue() = sinkCall.getArgument(0).getIntValue()
     )
   )