PS: Add helper predicates and classes to operations.

Author: MathiasVP

powershell/ql/lib/semmle/code/powershell/BinaryExpression.qll

@@ -5,6 +5,22 @@ class BinaryExpr extends @binary_expression, Expr {
 
   int getKind() { binary_expression(this, result, _, _) }
 
+  /** Gets an operand of this binary expression. */
+  Expr getAnOperand() {
+    result = this.getLeft()
+    or
+    result = this.getRight()
+  }
+
+  /** Holds if this binary expression has the operands `e1` and `e2`. */
+  predicate hasOperands(Expr e1, Expr e2) {
+    e1 = this.getLeft() and
+    e2 = this.getRight()
+    or
+    e1 = this.getRight() and
+    e2 = this.getLeft()
+  }
+
   Expr getLeft() { binary_expression(this, _, result, _) }
 
   Expr getRight() { binary_expression(this, _, _, result) }

powershell/ql/lib/semmle/code/powershell/controlflow/CfgNodes.qll

@@ -519,6 +519,50 @@ module ExprNodes {
 
     final StmtCfgNode getBase() { e.hasCfgChild(e.getBase(), this, result) }
   }
+
+  class UnaryExprChildMapping extends ExprChildMapping, UnaryExpr {
+    override predicate relevantChild(Ast n) { n = this.getOperand() }
+  }
+
+  class UnaryCfgNode extends ExprCfgNode {
+    override string getAPrimaryQlClass() { result = "UnaryExprCfgNode" }
+
+    override UnaryExprChildMapping e;
+
+    override UnaryExpr getExpr() { result = e }
+
+    final ExprCfgNode getOperand() { e.hasCfgChild(e.getOperand(), this, result) }
+  }
+
+  class BinaryExprChildMapping extends ExprChildMapping, BinaryExpr {
+    override predicate relevantChild(Ast n) { n = this.getLeft() or n = this.getRight() }
+  }
+
+  class BinaryCfgNode extends ExprCfgNode {
+    override string getAPrimaryQlClass() { result = "BinaryExprCfgNode" }
+
+    override BinaryExprChildMapping e;
+
+    override BinaryExpr getExpr() { result = e }
+
+    final ExprCfgNode getLeft() { e.hasCfgChild(e.getLeft(), this, result) }
+
+    final ExprCfgNode getRight() { e.hasCfgChild(e.getRight(), this, result) }
+  }
+
+  class OperationChildMapping extends ExprChildMapping instanceof Operation {
+    override predicate relevantChild(Ast n) { n = super.getAnOperand() }
+  }
+
+  class OperationCfgNode extends ExprCfgNode {
+    override string getAPrimaryQlClass() { result = "OperationCfgNode" }
+
+    override OperationChildMapping e;
+
+    override Operation getExpr() { result = e }
+
+    final ExprCfgNode getAnOperand() { e.hasCfgChild(this.getExpr().getAnOperand(), this, result) }
+  }
 }
 
 module StmtNodes {

powershell/ql/lib/semmle/code/powershell/internal/Internal.qll

@@ -2,10 +2,12 @@ module Private {
   import Parameter::Private
   import ExplicitWrite::Private
   import Argument::Private
+  import Operation::Private
 }
 
 module Public {
   import Parameter::Public
   import ExplicitWrite::Public
   import Argument::Public
+  import Operation::Public
 }

powershell/ql/lib/semmle/code/powershell/internal/Operation.qll

@@ -0,0 +1,31 @@
+import powershell
+
+module Private {
+  abstract private class AbstractOperation extends Expr {
+    abstract Expr getAnOperand();
+
+    abstract int getKind();
+  }
+
+  class BinaryOperation extends BinaryExpr, AbstractOperation {
+    final override Expr getAnOperand() { result = BinaryExpr.super.getAnOperand() }
+
+    final override int getKind() { result = BinaryExpr.super.getKind() }
+  }
+
+  class UnaryOperation extends UnaryExpr, AbstractOperation {
+    final override Expr getAnOperand() { result = UnaryExpr.super.getOperand() }
+
+    final override int getKind() { result = UnaryExpr.super.getKind() }
+  }
+
+  final class Operation = AbstractOperation;
+}
+
+module Public {
+  class Operation = Private::Operation;
+
+  class BinaryOperation = Private::BinaryOperation;
+
+  class UnaryOperation = Private::UnaryOperation;
+}