Add WS2812B library again, but this time without the .git folder in it

Author: rogerclarkmelbourne

STM32F1/libraries/WS2812B/README.md

@@ -0,0 +1,78 @@
+# WS2812B_STM32_Libmaple
+WS2812B (Neopixel) library for Arduino STM32 (Libmaple core)
+
+Written by Roger Clark www.rogerclark.net, from first principals
+
+This library uses SPI DMA to control a strip of WS2812B (NeoPixel) LEDS
+
+It should be generally compatible with the Adafruit NeoPixel library, 
+except I have not had chance to implement one or two of the lesser used functions
+
+Connect  Data In of the strip to SPI1 MOSI
+
+This library has only been tested on the WS2812B LED. It may not work with the older WS2812 or
+other types of addressable RGB LED, becuase it relies on a division multiple of the 72Mhz clock 
+frequence on the STM32 SPI to generate the correct width T0H pulse, of 400ns +/- 150nS
+SPI DIV32 gives a pulse width of 444nS which is well within spec for the WS2812B but
+is probably too long for the WS2812 which needs a 350ns pulse for T0H
+
+##Technical details
+
+The library uses SPI to send the mark/space encoded data to the LED's
+
+Each mark/space squarewave is generated by 3 bits of data
+A pixel 0 value is achieved by sending the bit pattern 100
+A pixel 1 value is achieved by sending the bit pattern 110
+
+Where the duration of each bit is 444nS
+Hence 100 generates a mark space value of 444/888nS
+and 110 generates a mark space value of 888/444nS
+
+This method results in the smallest storage requirement and the fastest send times,
+however because the 8 bit pixel channel data is encoded in 24 bits, (3 bytes) the values required in each of the 3 bytes to represent 
+a specific value is not easy to generate.
+
+The bit pattern in the 3 bytes is 
+88877766   65554443    33222111
+
+For speed of operation the values reqired for each byte for each of the 256 possible values is held in 3 separate 256 byte LUTS
+which were pre-computed by this function (which generates the full 24 bit pattern for a given input value (0-255)
+
+```
+uint32_t convert(uint8_t data)
+{
+  uint32_t out=0;
+  for(uint8_t mask = 0x80; mask; mask >>= 1)  
+  {
+    out=out<<3;
+    if (data & mask)
+    {
+      out = out | 0B110;//Bit high
+    }
+    else
+    {
+      out = out | 0B100;// bit low
+    }
+  }
+  return out;
+}
+```
+
+The STM32F103 has plenty of flash space (either 64 or 128k), so I used 256 byte LUTs even though the number of unique values in each LUT is 
+only 8,4 and 8 bytes respectively.
+However to use small LUTS requires shifting and masking of the input data, and the code was written with a preference for speed over binary size
+
+The encoded pixel buffer is 2 bytes longer than the actual encoded data.
+The first and last encoded bytes are all zeros. This is because the SPI hardware seems to preload MOSI with its output value before the start
+of the DMA transfer, which causes the first encoded pulse to be around 50ns longer than the subsequent bits, (around 490 or 500ns)
+This had the effect of causing the first LED to always think the MS bit of the green channel was set to High.
+
+So having the first encoded byte of zeros, is a work-around , as although the first encoded bit is still 490nS wide its a logic zero and is therefore
+not visible, becuase the default state is of the SPI when not transmitting data is logic zero
+The last byte was also set to all zeros, as occasionally MOSI seemed to be left set to logic high on completion of the SPI DMA send
+
+Adding these 2 bytes does slightly slow down the transfer, as it add 444ns * 8 = just over 3.5uS to both end.
+But the WS2812B theoretically requires a reset time of more than 50uS between transmissions, so 3.5uS can be part of that time.
+In reality the WS2812B seems to only need around 6uS of reset time, so for all practical purposes, there no delays are needed at all in the
+library to enforce the reset time, as the overead of the function call and the SPI DMA setup plus the 3.5uS gives the enough reset time.
+

STM32F1/libraries/WS2812B/examples/WS2812B_test/WS2812B_test.ino

@@ -0,0 +1,303 @@
+#include <WS2812B.h>
+
+#define NUM_LEDS 30
+/*
+ * Note. Library uses SPI1
+ * Connect the WS2812B data input to MOSI on your board.
+ * 
+ */
+WS2812B strip = WS2812B(NUM_LEDS);
+// Note. Gamma is not really supported in the library, its only included as some functions used in this example require Gamma
+uint8_t LEDGamma[] = {
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  1,  1,  1,  1,
+    1,  1,  1,  1,  1,  1,  1,  1,  1,  2,  2,  2,  2,  2,  2,  2,
+    2,  3,  3,  3,  3,  3,  3,  3,  4,  4,  4,  4,  4,  5,  5,  5,
+    5,  6,  6,  6,  6,  7,  7,  7,  7,  8,  8,  8,  9,  9,  9, 10,
+   10, 10, 11, 11, 11, 12, 12, 13, 13, 13, 14, 14, 15, 15, 16, 16,
+   17, 17, 18, 18, 19, 19, 20, 20, 21, 21, 22, 22, 23, 24, 24, 25,
+   25, 26, 27, 27, 28, 29, 29, 30, 31, 32, 32, 33, 34, 35, 35, 36,
+   37, 38, 39, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 50,
+   51, 52, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 66, 67, 68,
+   69, 70, 72, 73, 74, 75, 77, 78, 79, 81, 82, 83, 85, 86, 87, 89,
+   90, 92, 93, 95, 96, 98, 99,101,102,104,105,107,109,110,112,114,
+  115,117,119,120,122,124,126,127,129,131,133,135,137,138,140,142,
+  144,146,148,150,152,154,156,158,160,162,164,167,169,171,173,175,
+  177,180,182,184,186,189,191,193,196,198,200,203,205,208,210,213,
+215,218,220,223,225,228,231,233,236,239,241,244,247,249,252,255 };
+
+void setup() 
+{
+  strip.begin();// Sets up the SPI
+  strip.show();// Clears the strip, as by default the strip data is set to all LED's off.
+ // strip.setBrightness(8);
+}
+
+void loop() 
+{ 
+  colorWipe(strip.Color(0, 255, 0), 20); // Green
+  colorWipe(strip.Color(255, 0, 0), 20); // Red
+  colorWipe(strip.Color(0, 0, 255), 20); // Blue
+  rainbow(10);
+  rainbowCycle(10);
+  theaterChase(strip.Color(255, 0, 0), 20); // Red
+  theaterChase(strip.Color(0, 255, 0), 20); // Green
+  theaterChase(strip.Color(0, 0, 255), 20); // Blue
+  theaterChaseRainbow(10);
+  whiteOverRainbow(20,75,5);  
+  pulseWhite(5); 
+  delay(250);
+  fullWhite();
+  delay(250);
+  rainbowFade2White(3,3,1);
+}
+
+// Fill the dots one after the other with a color
+void colorWipe(uint32_t c, uint8_t wait) 
+{
+  for(uint16_t i=0; i<strip.numPixels(); i++) 
+  {
+      strip.setPixelColor(i, c);
+      strip.show();
+      delay(wait);
+  }
+}
+
+void rainbow(uint8_t wait) {
+  uint16_t i, j;
+
+  for(j=0; j<256; j++) {
+    for(i=0; i<strip.numPixels(); i++) 
+  {
+      strip.setPixelColor(i, Wheel((i+j) & 255));
+    }
+    strip.show();
+    delay(wait);
+  }
+}
+
+
+
+// Slightly different, this makes the rainbow equally distributed throughout
+void rainbowCycle(uint8_t wait) 
+{
+  uint16_t i, j;
+
+  for(j=0; j<256*5; j++) 
+  { // 5 cycles of all colors on wheel
+    for(i=0; i< strip.numPixels(); i++) 
+  {
+      strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
+    }
+    strip.show();
+    delay(wait);
+  }
+}
+
+// Input a value 0 to 255 to get a color value.
+// The colours are a transition r - g - b - back to r.
+uint32_t Wheel(byte WheelPos) 
+{
+  if(WheelPos < 85) 
+  {
+    return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
+  } 
+  else 
+  {
+    if(WheelPos < 170) 
+    {
+     WheelPos -= 85;
+     return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
+    } 
+    else 
+    {
+     WheelPos -= 170;
+     return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
+    }
+  }
+}
+
+//Theatre-style crawling lights.
+void theaterChase(uint32_t c, uint8_t wait) {
+  for (int j=0; j<10; j++) {  //do 10 cycles of chasing
+    for (int q=0; q < 3; q++) {
+      for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
+        strip.setPixelColor(i+q, c);    //turn every third pixel on
+      }
+      strip.show();
+
+      delay(wait);
+
+      for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
+        strip.setPixelColor(i+q, 0);        //turn every third pixel off
+      }
+    }
+  }
+}
+
+//Theatre-style crawling lights with rainbow effect
+void theaterChaseRainbow(uint8_t wait) {
+  for (int j=0; j < 256; j++) {     // cycle all 256 colors in the wheel
+    for (int q=0; q < 3; q++) {
+      for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
+        strip.setPixelColor(i+q, Wheel( (i+j) % 255));    //turn every third pixel on
+      }
+      strip.show();
+
+      delay(wait);
+
+      for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
+        strip.setPixelColor(i+q, 0);        //turn every third pixel off
+      }
+    }
+  }
+}
+
+void pulseWhite(uint8_t wait) {
+  for(int j = 0; j < 256 ; j++){
+      for(uint16_t i=0; i<strip.numPixels(); i++) {
+          strip.setPixelColor(i, strip.Color(0,0,0, LEDGamma[j] ) );
+        }
+        delay(wait);
+        strip.show();
+      }
+
+  for(int j = 255; j >= 0 ; j--){
+      for(uint16_t i=0; i<strip.numPixels(); i++) {
+          strip.setPixelColor(i, strip.Color(0,0,0, LEDGamma[j] ) );
+        }
+        delay(wait);
+        strip.show();
+      }
+}
+
+
+void rainbowFade2White(uint8_t wait, int rainbowLoops, int whiteLoops) {
+  float fadeMax = 100.0;
+  int fadeVal = 0;
+  uint32_t wheelVal;
+  int redVal, greenVal, blueVal;
+
+  for(int k = 0 ; k < rainbowLoops ; k ++){
+    
+    for(int j=0; j<256; j++) { // 5 cycles of all colors on wheel
+
+      for(int i=0; i< strip.numPixels(); i++) {
+
+        wheelVal = Wheel(((i * 256 / strip.numPixels()) + j) & 255);
+
+        redVal = red(wheelVal) * float(fadeVal/fadeMax);
+        greenVal = green(wheelVal) * float(fadeVal/fadeMax);
+        blueVal = blue(wheelVal) * float(fadeVal/fadeMax);
+
+        strip.setPixelColor( i, strip.Color( redVal, greenVal, blueVal ) );
+
+      }
+
+      //First loop, fade in!
+      if(k == 0 && fadeVal < fadeMax-1) {
+          fadeVal++;
+      }
+
+      //Last loop, fade out!
+      else if(k == rainbowLoops - 1 && j > 255 - fadeMax ){
+          fadeVal--;
+      }
+
+        strip.show();
+        delay(wait);
+    }
+  
+  }
+
+
+
+  delay(500);
+
+
+  for(int k = 0 ; k < whiteLoops ; k ++){
+
+    for(int j = 0; j < 256 ; j++){
+
+        for(uint16_t i=0; i < strip.numPixels(); i++) {
+            strip.setPixelColor(i, strip.Color(0,0,0, LEDGamma[j] ) );
+          }
+          strip.show();
+        }
+
+        delay(2000);
+    for(int j = 255; j >= 0 ; j--){
+
+        for(uint16_t i=0; i < strip.numPixels(); i++) {
+            strip.setPixelColor(i, strip.Color(0,0,0, LEDGamma[j] ) );
+          }
+          strip.show();
+        }
+  }
+
+  delay(500);
+
+
+}
+
+void whiteOverRainbow(uint8_t wait, uint8_t whiteSpeed, uint8_t whiteLength ) {
+  
+  if(whiteLength >= strip.numPixels()) whiteLength = strip.numPixels() - 1;
+
+  int head = whiteLength - 1;
+  int tail = 0;
+
+  int loops = 3;
+  int loopNum = 0;
+
+  static unsigned long lastTime = 0;
+
+
+  while(true){
+    for(int j=0; j<256; j++) {
+      for(uint16_t i=0; i<strip.numPixels(); i++) {
+        if((i >= tail && i <= head) || (tail > head && i >= tail) || (tail > head && i <= head) ){
+          strip.setPixelColor(i, strip.Color(0,0,0, 255 ) );
+        }
+        else{
+          strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
+        }
+        
+      }
+
+      if(millis() - lastTime > whiteSpeed) {
+        head++;
+        tail++;
+        if(head == strip.numPixels()){
+          loopNum++;
+        }
+        lastTime = millis();
+      }
+
+      if(loopNum == loops) return;
+    
+      head%=strip.numPixels();
+      tail%=strip.numPixels();
+        strip.show();
+        delay(wait);
+    }
+  }
+  
+}
+void fullWhite() {
+  
+    for(uint16_t i=0; i<strip.numPixels(); i++) {
+        strip.setPixelColor(i, strip.Color(0,0,0, 255 ) );
+    }
+      strip.show();
+}
+
+uint8_t red(uint32_t c) {
+  return (c >> 16);
+}
+uint8_t green(uint32_t c) {
+  return (c >> 8);
+}
+uint8_t blue(uint32_t c) {
+  return (c);
+}